sci-libs/htslib: add 1.15

Signed-off-by: David Seifert <soap@gentoo.org>

2 files changed, 53 insertions, 0 deletions

diff --git a/sci-libs/htslib/Manifest b/sci-libs/htslib/Manifest
index 230f4325182c..6cf20146c588 100644
--- a/sci-libs/htslib/Manifest
+++ b/sci-libs/htslib/Manifest
@@ -1 +1,2 @@
 DIST htslib-1.13.tar.bz2 4226834 BLAKE2B ae1f64e564f0f7bea80ea9d276b5d5b2b04fa3c8bd58f2c68966225b4324962f34d8a26b74267ab90dc530dfced1b9c01702d25918fd7a7c74e13913f00d5007 SHA512 16a3d61c115b71406bc4411a0c1176909166b52c4f7bb11614e398df4defaec4d09763413053e4d0d5916921c866d20019096d8fed866e77f9f1cafbd1e95b16
+DIST htslib-1.15.tar.bz2 4141168 BLAKE2B 20462b01e065b65de2b7df883cf61f9beb9ccca6fa3dc159c0aa7b303daf7c3779938f5eadbd3320e85ec19de105dc55e238c47a922ff6ace6fcaea2b0e95c19 SHA512 b87ce3eaa63a731d812953129f1c9aa857fe896ea9e924b7eb92173d8e624dd45e5582b3a97e7120ff7fe339e4d40148077424029626f50372b3f164093aa6cc
diff --git a/sci-libs/htslib/htslib-1.15.ebuild b/sci-libs/htslib/htslib-1.15.ebuild
new file mode 100644
index 000000000000..e651576d8a81
--- /dev/null
+++ b/sci-libs/htslib/htslib-1.15.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="C library for high-throughput sequencing data formats"
+HOMEPAGE="http://www.htslib.org/"
+SRC_URI="mirror://sourceforge/samtools/${PV}/${P}.tar.bz2"
+
+LICENSE="MIT"
+SLOT="0/3"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="+bzip2 curl +lzma"
+
+RDEPEND="
+	sys-libs/zlib
+	bzip2? ( app-arch/bzip2 )
+	curl? ( net-misc/curl )
+	lzma? ( app-arch/xz-utils )"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+
+	# upstream injects LDFLAGS into the .pc file,
+	# which is a big nono for QA
+	sed -e '/^\(static_l\|Libs.private\|Requires.private\)/d' \
+		-i htslib.pc.in || die
+}
+
+src_configure() {
+	econf \
+		--disable-gcs \
+		--disable-plugins \
+		--disable-s3 \
+		$(use_enable bzip2 bz2) \
+		$(use_enable curl libcurl) \
+		$(use_enable lzma)
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)"
+}
+
+src_install() {
+	default
+
+	# doesn't use libtool, can't disable static libraries
+	find "${ED}" -name '*.a' -delete || die
+}