sci-libs/scikit-learn: renamed sci-libs/scikits_learn

Closes: https://bugs.gentoo.org/665482
Closes: https://bugs.gentoo.org/717454

Signed-off-by: Aisha Tammy <gentoo@aisha.cc>
Signed-off-by: Aaron Bauman <bman@gentoo.org>

4 files changed, 158 insertions, 0 deletions

diff --git a/sci-libs/scikit-learn/Manifest b/sci-libs/scikit-learn/Manifest
new file mode 100644
index 000000000000..0a578c3504c5
--- /dev/null
+++ b/sci-libs/scikit-learn/Manifest
@@ -0,0 +1,2 @@
+DIST scikit-learn-0.22.2_p1.tar.gz 7034850 BLAKE2B 41c362ef6594e837a9fc798837e666fbb51e33954fdf700292650204fd9d1ab4fc4d1695890d02a24ad68f4dcc2d3cde8f0827eca70c6fb9a6f0e5c0d9c04fd5 SHA512 20bcda5c65f76bce9b71c5b5fb1b499f7f3a7a3f6fa5fade80a38dc658cb434e16e9d5a4906a9657157a5cc90a6d51080575d6e510207baa9f8b06c4fa761d5b
+DIST scikit-learn-0.23.2.tar.gz 7190564 BLAKE2B db90e3d05d9b563c6cd98a6820c27b541e757e3fb6c25262b720842811b9e26d41a4a9c1d73e675714573d84dab799a0c450e768f4a41a39a6a61f6930c4c79a SHA512 e9797185b1b9def3ee5525e9b72742784aeb78fe8b069bb5aeab1d0f4513cf738c4489ed894274606dea9d6a32ccd3df26170ce1951e443dc77f9287c372e8c5
diff --git a/sci-libs/scikit-learn/metadata.xml b/sci-libs/scikit-learn/metadata.xml
new file mode 100644
index 000000000000..0f62a4aec772
--- /dev/null
+++ b/sci-libs/scikit-learn/metadata.xml
@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>sci@gentoo.org</email>
+    <name>Gentoo Science Project</name>
+  </maintainer>
+  <longdescription lang="en">
+  scikits.learn is a python library for machine learning. It aims to
+  implement classic machine learning algorithms while remaining simple
+  and efficient.
+  </longdescription>
+  <upstream>
+    <remote-id type="pypi">scikit-learn</remote-id>
+    <remote-id type="sourceforge">scikit-learn</remote-id>
+  </upstream>
+</pkgmetadata>
diff --git a/sci-libs/scikit-learn/scikit-learn-0.22.2_p1-r1.ebuild b/sci-libs/scikit-learn/scikit-learn-0.22.2_p1-r1.ebuild
new file mode 100644
index 000000000000..517c34f0eb7f
--- /dev/null
+++ b/sci-libs/scikit-learn/scikit-learn-0.22.2_p1-r1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit distutils-r1
+
+MY_PV="${PV//_p/.post}"
+
+DESCRIPTION="Machine learning library for Python"
+HOMEPAGE="https://scikit-learn.org/stable/
+	https://github.com/scikit-learn/scikit-learn"
+SRC_URI="https://github.com/scikit-learn/scikit-learn/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+#ffhttps://github.com/scikit-learn/scikit-learn/archive/0.22.2.post1.tar.gz
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ~arm64 ~ppc64 x86"
+IUSE="examples"
+
+RDEPEND="
+	dev-python/wheel[${PYTHON_USEDEP}]
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/joblib[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	virtual/blas:=
+	virtual/cblas:=
+"
+DEPEND="
+	virtual/blas:=
+	virtual/cblas:=
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# scikits-learn now uses the horrible numpy.distutils automagic
+	export SCIPY_FCONFIG="config_fc --noopt --noarch"
+
+	# remove bundled cblas
+	rm -rf sklearn/src || die "failed to remove bundled cblas"
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	distutils-r1_python_compile ${SCIPY_FCONFIG}
+}
+
+python_test() {
+	distutils_install_for_testing ${SCIPY_FCONFIG}
+	pushd "${TEST_DIR}/lib" >/dev/null || die
+	pytest -vv || die "testing failed with ${EPYTHON}"
+	popd >/dev/null || die
+}
+
+python_install() {
+	distutils-r1_python_install ${SCIPY_FCONFIG}
+}
+
+python_install_all() {
+	find "${S}" -name \*LICENSE.txt -delete
+	distutils-r1_python_install_all
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+}
diff --git a/sci-libs/scikit-learn/scikit-learn-0.23.2.ebuild b/sci-libs/scikit-learn/scikit-learn-0.23.2.ebuild
new file mode 100644
index 000000000000..7b14c41b7a1a
--- /dev/null
+++ b/sci-libs/scikit-learn/scikit-learn-0.23.2.ebuild
@@ -0,0 +1,67 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+DISTUTILS_USE_SETUPTOOLS=no
+inherit distutils-r1
+
+DESCRIPTION="Machine learning library for Python"
+HOMEPAGE="https://scikit-learn.org/stable/
+	https://github.com/scikit-learn/scikit-learn"
+SRC_URI="https://github.com/scikit-learn/scikit-learn/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="examples"
+
+DEPEND="
+	virtual/blas:=
+	virtual/cblas:=
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/wheel[${PYTHON_USEDEP}]
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/joblib[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	dev-python/threadpoolctl[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# scikits-learn now uses the horrible numpy.distutils automagic
+	export SCIPY_FCONFIG="config_fc --noopt --noarch"
+
+	# remove bundled cblas
+	rm -rf sklearn/src || die "failed to remove bundled cblas"
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	distutils-r1_python_compile ${SCIPY_FCONFIG}
+}
+
+python_test() {
+	distutils_install_for_testing ${SCIPY_FCONFIG}
+	pushd "${TEST_DIR}/lib" >/dev/null || die
+	pytest -vv || die "testing failed with ${EPYTHON}"
+	popd >/dev/null || die
+}
+
+python_install() {
+	distutils-r1_python_install ${SCIPY_FCONFIG}
+}
+
+python_install_all() {
+	find "${S}" -name \*LICENSE.txt -delete
+	distutils-r1_python_install_all
+	if use examples; then
+		dodoc -r examples
+	fi
+}