sci-mathematics/glpk: fix configure typo per bug #611694, revbump to apply to users

Package-Manager: portage-2.3.3
Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>

1 files changed, 62 insertions, 0 deletions

diff --git a/sci-mathematics/glpk/glpk-4.61-r1.ebuild b/sci-mathematics/glpk/glpk-4.61-r1.ebuild
new file mode 100644
index 000000000000..0c701874fe58
--- /dev/null
+++ b/sci-mathematics/glpk/glpk-4.61-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools flag-o-matic toolchain-funcs
+
+DESCRIPTION="GNU Linear Programming Kit"
+LICENSE="GPL-3"
+HOMEPAGE="https://www.gnu.org/software/glpk/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+SLOT="0/40"
+IUSE="doc examples gmp odbc mysql static-libs"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~x86-macos"
+
+RDEPEND="
+	sci-libs/amd:0=
+	sci-libs/colamd:=
+	sys-libs/zlib:0=
+	gmp? ( dev-libs/gmp:0= )
+	mysql? ( virtual/mysql )
+	odbc? ( || ( dev-db/libiodbc:0 dev-db/unixODBC:0 ) )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.60-debundle-system-libs.patch
+)
+
+src_prepare() {
+	use odbc && [[ -z $(type -P odbc_config) ]] && \
+		append-cppflags $($(tc-getPKG_CONFIG) --cflags libiodbc)
+
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myconf
+	if use mysql || use odbc; then
+		myconf="--enable-dl"
+	else
+		myconf="--disable-dl"
+	fi
+
+	econf ${myconf} \
+		$(use_enable mysql) \
+		$(use_enable odbc) \
+		$(use_enable static-libs static) \
+		$(use_with gmp)
+}
+
+src_install() {
+	default
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	use doc && dodoc doc/*.pdf doc/notes/*.pdf doc/*.txt
+}