sys-apps/apparmor-utils: version bump 2.11.0

Package-Manager: Portage-2.3.3, Repoman-2.3.1

1 files changed, 59 insertions, 0 deletions

diff --git a/sys-apps/apparmor-utils/apparmor-utils-2.11.0.ebuild b/sys-apps/apparmor-utils/apparmor-utils-2.11.0.ebuild
new file mode 100644
index 000000000000..5ab1a7c9f1df
--- /dev/null
+++ b/sys-apps/apparmor-utils/apparmor-utils-2.11.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_4 )
+inherit perl-module python-r1 versionator
+
+MY_PV="$(get_version_component_range 1-2)"
+
+DESCRIPTION="Additional userspace utils to assist with AppArmor profile management"
+HOMEPAGE="http://apparmor.net/"
+SRC_URI="https://launchpad.net/apparmor/${MY_PV}/${MY_PV}/+download/apparmor-${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+DEPEND="dev-lang/perl
+	${PYTHON_DEPS}"
+RDEPEND="${DEPEND}
+	~sys-libs/libapparmor-${PV}[perl,python]
+	~sys-apps/apparmor-${PV}
+	dev-perl/Locale-gettext
+	dev-perl/RPC-XML
+	dev-perl/TermReadKey
+	virtual/perl-Data-Dumper
+	virtual/perl-Getopt-Long"
+
+S=${WORKDIR}/apparmor-${PV}/utils
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.10-shebang.patch"
+)
+
+src_compile() {
+	python_setup
+
+	# launches non-make subprocesses causing "make jobserver unavailable"
+	# error messages to appear in generated code
+	emake -j1
+}
+
+src_install() {
+	perl_set_version
+	emake DESTDIR="${D}" PERLDIR="${D}/${VENDOR_LIB}/Immunix" \
+		VIM_INSTALL_PATH="${D}/usr/share/vim/vimfiles/syntax" install
+
+	install_python() {
+		"${PYTHON}" "${S}"/python-tools-setup.py install --prefix=/usr \
+			--root="${D}" --version="${PV}"
+	}
+
+	python_foreach_impl install_python
+	python_replicate_script "${D}"/usr/bin/aa-easyprof "${D}"/usr/sbin/apparmor_status \
+		"${D}"/usr/sbin/aa-{audit,autodep,cleanprof,complain,disable,enforce,genprof,logprof,mergeprof,status,unconfined}
+}