proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 69 insertions, 0 deletions

diff --git a/sys-apps/proot/proot-5.1.0.ebuild b/sys-apps/proot/proot-5.1.0.ebuild
new file mode 100644
index 000000000000..9ab5a080e935
--- /dev/null
+++ b/sys-apps/proot/proot-5.1.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+MY_PN="PRoot"
+
+inherit eutils toolchain-funcs
+
+DESCRIPTION="User-space implementation of chroot, mount --bind, and binfmt_misc"
+HOMEPAGE="http://proot.me"
+SRC_URI="https://github.com/cedric-vincent/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="care test"
+
+RDEPEND="care? ( app-arch/libarchive:0= )
+	 sys-libs/talloc"
+DEPEND="${RDEPEND}
+	care? ( dev-libs/uthash )
+	test? ( dev-util/valgrind )"
+
+# Breaks sandbox
+RESTRICT="test"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_prepare() {
+	epatch  "${FILESDIR}/${PN}-3.2.1-makefile.patch" \
+		"${FILESDIR}/${PN}-2.3.1-lib-paths-fix.patch"
+	epatch_user
+}
+
+src_compile() {
+	# build the proot and care targets
+	emake -C src V=1 \
+		CC="$(tc-getCC)" \
+		CHECK_VERSION="true" \
+		CAREBUILDENV="ok" \
+		proot $(use care && echo "care")
+}
+
+src_install() {
+	if use care; then
+		dobin src/care
+		dodoc doc/care/*.txt
+	fi
+	dobin src/proot
+	newman doc/proot/man.1 proot.1
+	dodoc doc/proot/*.txt
+	dodoc -r doc/articles
+}
+
+src_test() {
+	emake -C tests -j1 CC="$(tc-getCC)"
+}
+
+pkg_postinst() {
+	if use care; then
+		elog "You have enabled 'care' USE flag, that builds and installs"
+		elog "dynamically linked care binary."
+		elog "Upstream does NOT support such way of building CARE,"
+		elog "it provides only prebuilt binaries."
+		elog "CARE also has known problems on hardened systems"
+		elog "Please do NOT file bugs about them to http://bugs.gentoo.org"
+	fi
+}