sys-apps/restorecond: bump to 2.9_rc1

Signed-off-by: Jason Zaman <perfinion@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

1 files changed, 55 insertions, 0 deletions

diff --git a/sys-apps/restorecond/restorecond-2.9_rc1.ebuild b/sys-apps/restorecond/restorecond-2.9_rc1.ebuild
new file mode 100644
index 000000000000..7e54ae96b8d6
--- /dev/null
+++ b/sys-apps/restorecond/restorecond-2.9_rc1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit toolchain-funcs
+
+MY_RELEASEDATE="20190125"
+
+MY_P="${P//_/-}"
+IUSE=""
+
+if [[ ${PV} == *9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/SELinuxProject/selinux.git"
+	S="${WORKDIR}/${MY_P}/${PN}"
+else
+	SRC_URI="https://github.com/SELinuxProject/selinux/releases/download/${MY_RELEASEDATE}/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~mips ~x86"
+	S="${WORKDIR}/${MY_P}"
+fi
+
+DESCRIPTION="Daemon to watch for creation and set default SELinux fcontexts"
+HOMEPAGE="https://github.com/SELinuxProject/selinux/wiki"
+
+LICENSE="GPL-2"
+SLOT="0"
+
+DEPEND=">=sys-libs/libsepol-${PV}:=
+	>=sys-libs/libselinux-${PV}:=
+	dev-libs/dbus-glib
+	dev-libs/libpcre:=
+	>=sys-libs/libcap-1.10-r10:="
+
+RDEPEND="${DEPEND}
+	!<sys-apps/policycoreutils-2.7_pre"
+
+src_prepare() {
+	default
+
+	sed -i 's/-Werror//g' "${S}"/Makefile || die "Failed to remove Werror"
+}
+
+src_compile() {
+	tc-export CC
+	default
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	rm -rf "${D}/etc/rc.d" || die
+
+	newinitd "${FILESDIR}/restorecond.init" restorecond
+}