sys-auth/pam_mysql: Stable revbump for dependency change

Closes: https://bugs.gentoo.org/666068
Package-Manager: Portage-2.3.49, Repoman-2.3.10

1 files changed, 45 insertions, 0 deletions

diff --git a/sys-auth/pam_mysql/pam_mysql-0.8.1-r1.ebuild b/sys-auth/pam_mysql/pam_mysql-0.8.1-r1.ebuild
new file mode 100644
index 000000000000..1cdc2f481e9d
--- /dev/null
+++ b/sys-auth/pam_mysql/pam_mysql-0.8.1-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit autotools pam
+
+DESCRIPTION="pam_mysql is a module for pam to authenticate users with mysql"
+HOMEPAGE="https://github.com/NigelCunningham/pam-MySQL"
+
+SRC_URI="https://github.com/NigelCunningham/pam-MySQL/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+DEPEND="
+	>=sys-libs/pam-0.72:0=
+	dev-db/mysql-connector-c:0=
+	openssl? ( dev-libs/openssl:0= )
+"
+RDEPEND="${DEPEND}"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="alpha amd64 ppc ~sparc x86"
+IUSE="openssl"
+S="${WORKDIR}/pam-MySQL-${PV}"
+
+DOCS=( AUTHORS ChangeLog NEWS README )
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--with-pam-mods-dir="$(getpam_mod_dir)"
+		$(use_with openssl)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	rm "${ED%/}$(getpam_mod_dir)/pam_mysql.la" || die
+}