sys-devel/gcc-config: Version bump to current git master, untested, no keywords

Package-Manager: Portage-2.3.8, Repoman-2.3.3

1 files changed, 50 insertions, 0 deletions

diff --git a/sys-devel/gcc-config/gcc-config-1.9.0.ebuild b/sys-devel/gcc-config/gcc-config-1.9.0.ebuild
new file mode 100644
index 000000000000..0a629aac7136
--- /dev/null
+++ b/sys-devel/gcc-config/gcc-config-1.9.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils toolchain-funcs multilib
+
+DESCRIPTION="Utility to manage compilers"
+HOMEPAGE="https://gitweb.gentoo.org/proj/gcc-config.git/"
+SRC_URI="mirror://gentoo/${P}.tar.xz
+	https://dev.gentoo.org/~dilfridge/distfiles/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+#KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
+IUSE=""
+
+RDEPEND=">=sys-apps/gentoo-functions-0.10"
+
+src_compile() {
+	emake CC="$(tc-getCC)"
+}
+
+src_install() {
+	emake \
+		DESTDIR="${D}" \
+		PV="${PV}" \
+		SUBLIBDIR="$(get_libdir)" \
+		install
+}
+
+pkg_postinst() {
+	# Scrub eselect-compiler remains
+	rm -f "${ROOT}"/etc/env.d/05compiler &
+
+	# Make sure old versions dont exist #79062
+	rm -f "${ROOT}"/usr/sbin/gcc-config &
+
+	# We not longer use the /usr/include/g++-v3 hacks, as
+	# it is not needed ...
+	rm -f "${ROOT}"/usr/include/g++{,-v3} &
+
+	# Do we have a valid multi ver setup ?
+	local x
+	for x in $(gcc-config -C -l 2>/dev/null | awk '$NF == "*" { print $2 }') ; do
+		gcc-config ${x}
+	done
+
+	wait
+}