sys-devel/llvm-roc: New ebuild for llvm-roc 3.0.0

Signed-off-by: Wilfried Holzke <gentoo@holzke.net>
Package-Manager: Portage-2.3.79, Repoman-2.3.16
Closes: https://github.com/gentoo/gentoo/pull/14149
Signed-off-by: Craig Andrews <candrews@gentoo.org>

1 files changed, 57 insertions, 0 deletions

diff --git a/sys-devel/llvm-roc/llvm-roc-3.0.0.ebuild b/sys-devel/llvm-roc/llvm-roc-3.0.0.ebuild
new file mode 100644
index 000000000000..af16a02096ed
--- /dev/null
+++ b/sys-devel/llvm-roc/llvm-roc-3.0.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils
+
+DESCRIPTION="Radeon Open Compute llvm,lld,clang"
+HOMEPAGE="https://github.com/RadeonOpenCompute/ROCm/"
+SRC_URI="https://github.com/RadeonOpenCompute/llvm-project/archive/roc-ocl-${PV}.tar.gz -> llvm-roc-ocl-${PV}.tar.gz"
+
+LICENSE="UoI-NCSA rc BSD public-domain"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="debug"
+
+RDEPEND="virtual/cblas
+	 dev-libs/rocr-runtime"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/llvm-project-roc-ocl-${PV}/llvm"
+
+CMAKE_BUILD_TYPE=RelWithDebInfo
+
+src_prepare() {
+	cd "${WORKDIR}/llvm-project-roc-ocl-${PV}"
+	eapply "${FILESDIR}/${P}-add_libraries.patch"
+	eapply_user
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr/lib/llvm/roc"
+		-DLLVM_ENABLE_PROJECTS="clang;lld"
+		-DLLVM_TARGETS_TO_BUILD="AMDGPU;X86"
+		-DLLVM_BUILD_DOCS=NO
+		-DLLVM_ENABLE_OCAMLDOC=OFF
+		-DLLVM_ENABLE_SPHINX=NO
+		-DLLVM_ENABLE_DOXYGEN=OFF
+		-DLLVM_INSTALL_UTILS=ON
+		-DLLVM_VERSION_SUFFIX=roc
+		-DOCAMLFIND=NO
+	)
+
+	use debug || local -x CPPFLAGS="${CPPFLAGS} -DNDEBUG"
+
+	cmake-utils_src_configure
+}
+
+src_install(){
+	cmake-utils_src_install
+	cat > "99${PN}" <<-EOF
+		LDPATH="${EROOT}/usr/lib/llvm/roc/lib"
+	EOF
+	doenvd "99${PN}"
+}