sys-fabric/mstflint: Bump to version 4.14.0_p3

Package-Manager: Portage-3.0.3, Repoman-3.0.0
Signed-off-by: Zac Medico <zmedico@gentoo.org>

1 files changed, 46 insertions, 0 deletions

diff --git a/sys-fabric/mstflint/mstflint-4.14.0_p3.ebuild b/sys-fabric/mstflint/mstflint-4.14.0_p3.ebuild
new file mode 100644
index 000000000000..0beaafa4fa00
--- /dev/null
+++ b/sys-fabric/mstflint/mstflint-4.14.0_p3.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Mstflint - an open source version of MFT (Mellanox Firmware Tools)"
+HOMEPAGE="https://github.com/Mellanox/mstflint"
+LICENSE="|| ( GPL-2 BSD-2 )"
+KEYWORDS="~amd64 ~x86"
+EGIT_COMMIT="f8056f78a64debbdbb2522db7181848b9203e428"
+MY_PV=${PV/_p/-}
+MY_P=""
+SRC_URI="https://github.com/Mellanox/mstflint/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+IUSE="adb-generic-tools inband ssl"
+SLOT="0"
+RDEPEND="dev-db/sqlite:3=
+	sys-libs/zlib:=
+	inband? ( sys-fabric/libibmad )
+	adb-generic-tools? (
+		dev-libs/boost:=
+		dev-libs/expat:=
+	)
+	ssl? ( dev-libs/openssl:= )"
+DEPEND="${RDEPEND}"
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+src_prepare() {
+	default
+	echo '#define TOOLS_GIT_SHA "'${EGIT_COMMIT}'"' > ./common/gitversion.h || die
+}
+
+src_configure() {
+	eautoreconf
+	econf $(use_enable inband) $(use_enable ssl openssl) $(use adb-generic-tools && printf -- '--enable-adb-generic-tools')
+}
+
+src_compile() {
+	if use adb-generic-tools; then
+		pushd ext_libs/json >/dev/null || die
+		emake
+		popd >/dev/null || die
+	fi
+	default
+}