sys-kernel/ck-sources: version 4.9.137

updated to genpatches-4.9-141

Package-Manager: Portage-2.3.51, Repoman-2.3.11
Signed-off-by: Sarah White <kuzetsa@poindexter.ovh>
Signed-off-by: Göktürk Yüksek <gokturk@gentoo.org>

1 files changed, 52 insertions, 0 deletions

diff --git a/sys-kernel/ck-sources/ck-sources-4.9.137.ebuild b/sys-kernel/ck-sources/ck-sources-4.9.137.ebuild
new file mode 100644
index 000000000000..da12748fbcc2
--- /dev/null
+++ b/sys-kernel/ck-sources/ck-sources-4.9.137.ebuild
@@ -0,0 +1,52 @@
+# Copyright 2018 kuzetsa℠ and others
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+ETYPE="sources"
+KEYWORDS="~amd64 ~x86"
+
+HOMEPAGE="https://dev.gentoo.org/~mpagano/genpatches/
+	http://kernel.kolivas.org/"
+
+IUSE="experimental"
+
+K_WANT_GENPATCHES="base extras experimental"
+K_GENPATCHES_VER="141"
+K_SECURITY_UNSUPPORTED="1"
+K_DEBLOB_AVAILABLE="1"
+
+PYTHON_COMPAT=( python2_7 )
+inherit python-any-r1 kernel-2
+detect_version
+detect_arch
+
+DEPEND="deblob? ( ${PYTHON_DEPS} )"
+
+K_BRANCH_ID="${KV_MAJOR}.${KV_MINOR}"
+
+DESCRIPTION="Gentoo's genpatches for Linux ${K_BRANCH_ID}, with Con Kolivas' MuQSS process scheduler."
+
+MUQSS_VERSION="150"
+MUQSS_FILE="${K_BRANCH_ID}-sched-MuQSS_${MUQSS_VERSION}.patch"
+MUQSS_BASE_URL="http://ck.kolivas.org/patches/muqss/4.0"
+
+# clearly identify package name in distdir
+MUQSS_DISTNAME="${PN}-${K_BRANCH_ID}-muqss.patch"
+
+CK_LVER_URL="${MUQSS_BASE_URL}/${K_BRANCH_ID}"
+CK_URI="${CK_LVER_URL}/${MUQSS_FILE} -> ${MUQSS_DISTNAME}"
+
+# solves bug #606866 (Fix build for CONFIG_FREEZER disabled.x)
+FRZR_HASH="7de569950716147ed436b27936628ee3ab5b45cc"
+FRZR_FILE="${PN}-4.9-freezer-fix.patch"
+FRZR_URI="https://github.com/ckolivas/linux/commit/${FRZR_HASH}.patch -> ${FRZR_FILE}"
+
+SRC_URI="${KERNEL_URI} ${GENPATCHES_URI} ${ARCH_URI} ${CK_URI} ${FRZR_URI}"
+
+UNIPATCH_LIST="${DISTDIR}/${MUQSS_DISTNAME} ${DISTDIR}/${FRZR_FILE}"
+UNIPATCH_STRICTORDER="yes"
+
+pkg_setup() {
+	use deblob && python-any-r1_pkg_setup
+	kernel-2_pkg_setup
+}