sys-kernel/gentoo-kernel-bin: add 5.4.152-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index da93c721e735..074f18793f2d 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -74,6 +74,7 @@ DIST gentoo-kernel-5.4.151-1.amd64.xpak 61415626 BLAKE2B bbb924ccc35a3dff6cc2284
 DIST gentoo-kernel-5.4.151-1.arm64-r1.xpak 57973056 BLAKE2B 2b78681505963b42718c0d899a72643d8193e43d6f5a9709855ef2e7b748aed99c9980e4852dc4a860bfdaf713d226f4a1582790cb9ac9058715c2a94037327f SHA512 1ab279e632f0f17f7efeb14735c0d7e62b51a597c5e5aeb5bbaa1ea34db662d5668f865cf7024053969baf8673fbfeebf701d6989eb43fffb9356d40b7711363
 DIST gentoo-kernel-5.4.151-1.x86.xpak 53172777 BLAKE2B 59036b5c78b49fa125f67e7066ea6e32dfc3297f0de96993a5dc8517708cc844bd1696cf573016a9f6ecec01bfcda47bf057795eecbc11d8080e1a2978eb6fe3 SHA512 ba34d560c7405cd2b6478b5e78bb8bd371d95434a30e9cc78d10df301be6dd4737a4ef84ac1c824b88f921c4f9a35f889307072355d1ed69a9a049a1551b3256
 DIST gentoo-kernel-5.4.152-1.amd64.xpak 61376142 BLAKE2B f6eed297fe1a9fbf5882522f1a2b4b154f0900b1dd38e8fa7f6e6d3dd8c8d613e8218c9eae6bb9a039c6f049910732218d9529567acf346761daf0d1da3923cb SHA512 2b4559c270a7479039288092e17b1c084b01e9d44b0207c7eb289074667fc53ec6b670f370ee9e4bc0d175aa5ce1fa38ad6d0a739c3fb852499326fa5b58ac3f
+DIST gentoo-kernel-5.4.152-1.arm64-r1.xpak 58006425 BLAKE2B 73697415be296fb5e259ad566cb7cea46cc755a3162ec113b4e34f04fe3e1a1bea134f58fbd4cb7026f37e200503229de82b1a02db8968e73133c996357aafde SHA512 6a5063e1c755b189d19b0f52c23c07eab941849172f3e242ce83254794dfba36d5c6983f75d55db04d01c54e99095e8de0220a28307da9ac48a163fa58fd354c
 DIST gentoo-kernel-5.4.152-1.x86.xpak 53160478 BLAKE2B 64bb7c24de23fb7bffabdd56e1d79b0ebf2d1ff9e3ab6bee70e454a4a94106d5eaa956886e78d264c204b9d7214d1664418113b92b27a59c123a39f89705e9dc SHA512 7afa3a380453b64e54153e59cb552ccf1bbe85eab665646bf0f654e3b8c0edbd25bd57acf93e2deed9d1307e5dad2f7ef037bf28da0d8d9681c9ce05c9ebdcba
 DIST linux-5.10.tar.xz 116606704 BLAKE2B b923d7b66309224f42f35f8a5fa219421b0a9362d2adacdadd8d96251f61f7230878ea297a269a7f3b3c56830f0b177e068691e1d7f88501a05653b0a13274d1 SHA512 95bc137d0cf9148da6a9d1f1a878698dc27b40f68e22c597544010a6c591ce1b256f083489d3ff45ff77753289b535135590194d88ef9f007d0ddab3d74de70e
 DIST linux-5.13.tar.xz 119297284 BLAKE2B 9c4c12e2394dec064adff51f7ccdf389192eb27ba7906db5eda543afe3d04afca6b9ea0848a057571bf2534eeb98e1e3a67734deff82c0d3731be205ad995668 SHA512 a8edf97e9d38a49f1be2bde1e29ad96274bb2c6f7e8a2bebaa1161dd4df9cabcbaec4ff644c45bee94f86ae47725087d6deed0cd954209cec717621d137db85e
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.152-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.152-r1.ebuild
new file mode 100644
index 000000000000..3b97f74d1041
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.152-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 4 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64-r1.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}