sys-kernel/gentoo-kernel-bin: bump 5.10.20 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index bff25658eea6..f8bf35143d2d 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -20,6 +20,7 @@ DIST gentoo-kernel-5.10.19-1.amd64.xpak 64036559 BLAKE2B 8f71ea8599f8d26931e6f43
 DIST gentoo-kernel-5.10.19-1.arm64.xpak 59222742 BLAKE2B 0d5468611285d6153a74c597f92c5127322c668b88aa5e20c94c7ba5546a7b33077c769e722e1f1f94f8df907a7e12731b99cf3a926cb1222482248f4d9334a0 SHA512 51601d08269b564894e1d6b27a16e0a7f928c86c83e996efd7efa17caf1a0dcf9ada93eecce72dbb322a952c5261f0056612e1d496fdd122d1e5bb567300fcb2
 DIST gentoo-kernel-5.10.19-1.x86.xpak 56996359 BLAKE2B 58e9d8e9a3c28e95a25f91fa2b7a0e70103b976d52e44ab37ee1d69e59ed4b0ae85078208e5843a1c1d03672ca00b3b12382a4d22a969d34a895b6081123cf1d SHA512 c9d7b41a60032a2b5273c30df01a22300b1a95029c768cb89fa6f1b49d79bd4f0a965766735b418e24f679e534dd545841cbc4749a6f5ce455e91124c4428eee
 DIST gentoo-kernel-5.10.20-1.amd64.xpak 64025164 BLAKE2B 05812b0eae411959bc3a65347bff20770273a91033f23e9a12c0673ac29184d049b8cdb62180c26b209e8cfbd4e3a4e79f8fb84525f0119d22b799a1833b5e38 SHA512 13739db7ae56e6c025cb04d835128c8de026a33476d5b1249c5d05719437fd6626e71e74aaf2b7e68edbee930b78bae68c41fcdd0429c8ff108bad6f63bb47d5
+DIST gentoo-kernel-5.10.20-1.arm64.xpak 59166505 BLAKE2B b8a591f53961753da42c1d0c5f946ee7e6d01469f25ace5c22d27a84c404d427521864893879d9d6be6886b96dfdd667c16c2cd981cb699460465594b577c817 SHA512 c12739add0585e4e9c9b2517f8ebb286083fab8b5c64b2bd2cac0bc96344b2a1b7f8834fae8e4a81512aedf797fe86577a12641af0bac012d07fe4fccf36159d
 DIST gentoo-kernel-5.10.20-1.x86.xpak 56974811 BLAKE2B 8d636a1af81de6f7a77235610459719c046b980103ee2c67122efb27554c20491b1febb05849d4cab97a0ceb5368449031de6b3b3e97f0cb41aca0bf372ae6a0 SHA512 ddd16c0b92bc86ac1f38eb0ed9fdfede66dfb16518e4e4bbe646c5db82a398e2ce86180e228b874cf419cbae895cfb1c2b0b11c22a499670ca516648e7f6f190
 DIST gentoo-kernel-5.11.2-1.amd64.xpak 64830406 BLAKE2B f9c5d0591a175e497e3ff9f9c12e855e0c7db90aaf28fef5bbc695604c5745e13e3cd16001eb75216c55868497954a58738a7eca2314f077548650ae27b73620 SHA512 9a05cf8ce3218ac7e6b880624cbdc67d7fa221f0440f920de70f883a33978df08297184eeeb7a5b3c420da34ba7cb9ebc38f11c9a4979cf5d8a5c7a33e82b85a
 DIST gentoo-kernel-5.11.2-1.arm64.xpak 59866719 BLAKE2B 5c8e59242ac3512488afbc1335845294f6ed6b5f7cf0674c4655689b4e93284b110295da479c14f3bd70111c5f652a2c7c641bd34b06f9d7b21bacdb3965b746 SHA512 978891967b1b2c59ca1d4e77bd7d622585532e39cdaceae087a72c6f72d57764cd9dcdcad918ddb1c2d92a42ddc9859baf532971a280cbbe7c4811acb7cc3f5c
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.20-r3.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.20-r3.ebuild
new file mode 100644
index 000000000000..18c02d4c0f39
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.20-r3.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}
+	!sys-kernel/vanilla-kernel:${SLOT}
+	!sys-kernel/vanilla-kernel-bin:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${PV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${PV}" \
+		"usr/src/linux-${PV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${PV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${PV}"/ || die
+}