sys-kernel/linux-headers: bump up to 5.3

Package-Manager: Portage-2.3.76, Repoman-2.3.17
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>

1 files changed, 46 insertions, 0 deletions

diff --git a/sys-kernel/linux-headers/linux-headers-5.3.ebuild b/sys-kernel/linux-headers/linux-headers-5.3.ebuild
new file mode 100644
index 000000000000..c9062470d4f5
--- /dev/null
+++ b/sys-kernel/linux-headers/linux-headers-5.3.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+ETYPE="headers"
+H_SUPPORTEDARCH="alpha amd64 arc arm arm64 avr32 cris frv hexagon hppa ia64 m32r m68k metag microblaze mips mn10300 nios2 openrisc ppc ppc64 riscv s390 score sh sparc x86 xtensa"
+inherit kernel-2
+detect_version
+
+PATCH_PV=${PV} # to ease testing new versions against not existing patches
+PATCH_VER="1"
+SRC_URI="${KERNEL_URI}
+	${PATCH_VER:+mirror://gentoo/gentoo-headers-${PATCH_PV}-${PATCH_VER}.tar.xz}
+	${PATCH_VER:+https://dev.gentoo.org/~slyfox/distfiles/gentoo-headers-${PATCH_PV}-${PATCH_VER}.tar.xz}
+"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+DEPEND="app-arch/xz-utils
+	dev-lang/perl"
+RDEPEND=""
+
+S=${WORKDIR}/linux-${PV}
+
+src_unpack() {
+	unpack ${A}
+}
+
+src_prepare() {
+	default
+
+	[[ -n ${PATCH_VER} ]] && eapply "${WORKDIR}"/${PATCH_PV}/*.patch
+}
+
+src_install() {
+	kernel-2_src_install
+
+	# hrm, build system sucks
+	find "${ED}" '(' -name '.install' -o -name '*.cmd' ')' -delete
+	find "${ED}" -depth -type d -delete 2>/dev/null
+}
+
+src_test() {
+	emake ARCH=$(tc-arch-kernel) headers_check
+}