sys-kernel/gentoo-kernel-bin: bump to 5.11.16 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 116 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 2e82b574b0bf..995aeb2e38bc 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -51,6 +51,7 @@ DIST gentoo-kernel-5.11.15-1.amd64.xpak 64702205 BLAKE2B 37b1fc79595bd4f12561f9b
 DIST gentoo-kernel-5.11.15-1.arm64.xpak 59826678 BLAKE2B 66573bd61c3587bc7da7fbc49d8e40d2ce3cf3847b9a0af11633c0a173e7ab50a4156a576b3535c8d9448d529b303350001f9b74c98e53ffdc54e9ead00b8983 SHA512 b245a1ee0e4985b49e6897bd876a8d8da1c1268752bf6286d8d7dae128d8c1d05b7cb537f9791011fefc0949cdbf7e5e598835b27583bde9dbbd76cbfaa75b77
 DIST gentoo-kernel-5.11.15-1.x86.xpak 57616556 BLAKE2B 8eeae06459bf26979992d424e6e27ca77b9a58bf0be78a07df344b8d314b6df52a584fe92094306d73d775950ae1394b1679dd39209acb1df5a80a6a04811719 SHA512 6eb588aae81446bc1a53327fd1be94ed415f8254372439d739aaf4e170004c208ce25e50366a493a023ac00addddd343f410ce63385f0a8504c15c684c01be99
 DIST gentoo-kernel-5.11.16-1.amd64.xpak 65844402 BLAKE2B 13a0ffb59cfb9ade1f99ce6ec03c55e4e9409cd3fcd95c2063e1625f624062eeb114c2cd4ccf071e2a5119e8a6d2f5feff1f93ef924a6d2c25c80331da888bdc SHA512 f4c90f3057e7c43745708b3213306d0929f43bbe1a193f5c1a7f54a3937f40c58d4092c99f9997ea3068d1b920a1a1af4cdd60ee0dd7b2621dfcd08a0bce0bc4
+DIST gentoo-kernel-5.11.16-1.arm64.xpak 82054177 BLAKE2B 675c8b55f9d10055bb9579868228668bdd8b65c930edc5fe389c6002824f9d6fbcebd730ed4ec60029bcc866a8e83f15134dc73b2d45987a6ac18eadb62808ef SHA512 2f71782c5180b976a517d172250163ba6e40d9a7477c52a25adfc01c9bd340112e11d865597b7bea7b8a6461eb64a5fb6b4f3268dac12b0596b6523e9476ab80
 DIST gentoo-kernel-5.11.16-1.x86.xpak 57639335 BLAKE2B 2bb1d74691e8808ed4274b617dcf2920f5b5d1e1997ab3e336afb2d909dd4221a8acabe58b50cb90853e556caa64a2240cf6844cfde515286e7644a1463e065f SHA512 8cb39baef55953fa39a8ff6884ba27ad7555472bdac99689de1965e247fab9cc1874584a1b023457d44a80b4c7482bb92133f016323be94fc93e23b34f116952
 DIST gentoo-kernel-5.4.109-1.amd64.xpak 61197533 BLAKE2B d192b84c8e00a992256d44bce33975e29f7ae330a62a5902df14ca08ac5222c3bdbcb1ac27df36db615deecd7af7e264842c2aa358e4cc54e830f3507f5ad034 SHA512 33f192621fa3aa692e7b77897e57e50c7af81cb3ba6a40fd090bdafb5ed7b83dc83438028fc6999723e7f82a22635462746a92ced5439f136c56e0559c85b945
 DIST gentoo-kernel-5.4.109-1.arm64.xpak 56430663 BLAKE2B 6079b762ab5cdeb0c745a1a030e4a3af36883588c88dcb8c8cd811aa47d7cbaebc573b152f01fed451dbbfda1ec89ed400270e6fda4e3e1df1aec497b3f7815a SHA512 2d29230577255473618d698363af8c7ef8dd9dd3dcaeaec8fc8802e453838d2c1685e001a6ceb784f6c6ab77fb2b991366e213fec9c45b5763a3a5f57674cef7
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.16-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.16-r1.ebuild
new file mode 100644
index 000000000000..2760e617c656
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.16-r1.ebuild
@@ -0,0 +1,115 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}