www-client/opera-developer: remove old

Signed-off-by: Stephan Hartmann <sultan@gentoo.org>

2 files changed, 0 insertions, 166 deletions

diff --git a/www-client/opera-developer/Manifest b/www-client/opera-developer/Manifest
index b5189f57bee9..30c69d1273ef 100644
--- a/www-client/opera-developer/Manifest
+++ b/www-client/opera-developer/Manifest
@@ -1,4 +1,3 @@
-DIST opera-developer_95.0.4618.0_amd64.deb 99587420 BLAKE2B 10d13d6edfe3195b07facae22bee2454ef429305e35ea51d6360dc95c0139770415a0c762671340f6c283388cbb4be73a7360b81ada0f8f691fe7a99e6b1e036 SHA512 6334eb6c824a7ca119933a2695b3337290c70aa4a4a67e74b3376108cded7690e8969c7c83139f5dd02bb29b633b650304b6d7cf73afd9a441740031d75a8ca6
 DIST opera-developer_95.0.4625.0_amd64.deb 98610092 BLAKE2B 7146c756a23b12133c5c57dbe282ba47cc9fbbd4bdd6937b2c88d59d8fd9e76830a1f14c1dc093d4d047862756a85e4dcd8584e12230cae798cc0468bcd6da44 SHA512 d6c47ec5e1972781eedefcc5fc1aa5a0e65a4e2065b8de89d4388a9412f1f85df4b48dcadd181511d67891b9cb7537e1aad02eca936694a34ba6ee22bd4e908d
 DIST opera-developer_95.0.4632.0_amd64.deb 98941292 BLAKE2B 92ceb4005724e31586a15bbf8fa7232bcd7265d6e7fc16339d3dde2cb34110bc66d9fefe3f61d9b6d4ed366428b6b4c55e1b650a74d55b78fcc0bbc44f8795c1 SHA512 3c63e709b4b555b2d0ca9b68c43eef2d835150644536eed4619d9f8d1effb815d3aa391663ba2433206122440723931b7e23d7d2689bd0b199e10a5620840061
 DIST opera-developer_96.0.4640.0_amd64.deb 99427424 BLAKE2B ab8cb33d294a7582ec50f1da2c9edf6dd1ebeeb5d18f439154b5a237724a8e4aebb7b2c43333074a1f346e6f75e5775080ace0a7517148fb07147a83d8817e4a SHA512 40db739377493e48d377567780566b6cbd0768bcb244b7529d5baf0775f6f75a173c1ae33793068f8a14c7c1b6bb53879b9dc55108aaab8a115c107b887f1c8b
diff --git a/www-client/opera-developer/opera-developer-95.0.4618.0-r1.ebuild b/www-client/opera-developer/opera-developer-95.0.4618.0-r1.ebuild
deleted file mode 100644
index 4d1c6dc76dc6..000000000000
--- a/www-client/opera-developer/opera-developer-95.0.4618.0-r1.ebuild
+++ /dev/null
@@ -1,165 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-CHROMIUM_LANGS="
-	bg bn ca cs da de el en-GB en-US es-419 es fil fi fr hi hr hu id
-	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
-	zh-CN zh-TW
-"
-
-# These are intended for ebuild maintainer use to force RPM if DEB is not available.
-: ${OPERA_FORCE_RPM=no}
-
-inherit chromium-2 pax-utils xdg
-
-if [[ ${OPERA_FORCE_RPM} == yes ]]; then
-	inherit rpm
-	OPERA_ARCHIVE_EXT="rpm"
-else
-	inherit unpacker
-	OPERA_ARCHIVE_EXT="deb"
-fi
-
-DESCRIPTION="A fast and secure web browser"
-HOMEPAGE="https://www.opera.com/"
-LICENSE="OPERA-2018"
-SLOT="0"
-
-SRC_URI_BASE=(
-	"https://download1.operacdn.com/pub/${PN}"
-	"https://download2.operacdn.com/pub/${PN}"
-	"https://download3.operacdn.com/pub/${PN}"
-	"https://download4.operacdn.com/pub/${PN}"
-)
-
-if [[ ${PN} == opera ]]; then
-	MY_PN=${PN}-stable
-	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
-else
-	MY_PN=${PN}
-fi
-
-KEYWORDS="-* ~amd64"
-
-FFMPEG_VERSION="109.0.5414.25"
-
-SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}
-	proprietary-codecs? (
-		mirror+https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
-	)"
-
-IUSE="+proprietary-codecs +suid qt5"
-RESTRICT="bindist mirror strip"
-
-RDEPEND="
-	>=app-accessibility/at-spi2-core-2.46.0:2
-	dev-libs/expat
-	dev-libs/glib:2
-	dev-libs/nspr
-	dev-libs/nss
-	gnome-base/gsettings-desktop-schemas
-	media-libs/alsa-lib
-	media-libs/mesa[gbm(+)]
-	net-misc/curl
-	net-print/cups
-	sys-apps/dbus
-	sys-libs/glibc
-	x11-libs/cairo
-	x11-libs/gdk-pixbuf
-	x11-libs/gtk+:3
-	x11-libs/libdrm
-	x11-libs/libxcb
-	x11-libs/libxkbcommon
-	x11-libs/libxshmfence
-	x11-libs/libX11
-	x11-libs/libXcomposite
-	x11-libs/libXdamage
-	x11-libs/libXext
-	x11-libs/libXfixes
-	x11-libs/libXrandr
-	x11-libs/pango
-	qt5? (
-		dev-qt/qtcore:5
-		dev-qt/qtgui:5[X]
-		dev-qt/qtwidgets:5
-	)
-"
-
-QA_PREBUILT="*"
-S=${WORKDIR}
-OPERA_HOME="opt/opera${PN#opera}"
-
-pkg_pretend() {
-	# Protect against people using autounmask overzealously
-	use amd64 || die "opera only works on amd64"
-}
-
-pkg_setup() {
-	chromium_suid_sandbox_check_kernel_config
-}
-
-src_unpack() {
-	:
-}
-
-src_install() {
-	dodir /
-	cd "${ED}" || die
-	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
-		rpm_src_unpack "${A[0]}"
-	else
-		unpacker
-	fi
-
-	# move to /opt, bug #573052
-	mkdir -p "${OPERA_HOME%${PN}}"
-	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
-		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
-	else
-		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
-	fi
-	rm -r "usr/lib" || die
-
-	# disable auto update
-	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
-
-	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
-		rm "${OPERA_HOME}/setup_repo.sh" || die
-	else
-		rm -r "usr/share/lintian" || die
-
-		# fix docs
-		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
-		gzip -d usr/share/doc/${PF}/changelog.gz || die
-	fi
-
-	# fix desktop file
-	sed -i \
-		-e 's|^TargetEnvironment|X-&|g' \
-		usr/share/applications/${PN}.desktop || die
-
-	# remove unused language packs
-	pushd "${OPERA_HOME}/localization" > /dev/null || die
-	chromium_remove_language_paks
-	popd > /dev/null || die
-
-	# setup opera symlink
-	rm "usr/bin/${PN}" || die
-	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
-
-	# install proprietary codecs
-	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
-	if use proprietary-codecs; then
-		mv lib_extra "${OPERA_HOME}"
-	fi
-
-	if ! use qt5; then
-		rm "${OPERA_HOME}/libqt5_shim.so" || die
-	fi
-
-	# pax mark opera, bug #562038
-	pax-mark m "${OPERA_HOME}/opera"
-	# enable suid sandbox if requested
-	use suid && fperms 4711 "/${OPERA_HOME}/opera_sandbox"
-}