x11-libs/gl2ps: Bump to version 1.3.9

Package-Manager: Portage-2.3.3, Repoman-2.3.1

1 files changed, 54 insertions, 0 deletions

diff --git a/x11-libs/gl2ps/gl2ps-1.3.9.ebuild b/x11-libs/gl2ps/gl2ps-1.3.9.ebuild
new file mode 100644
index 000000000000..ac5f65d23683
--- /dev/null
+++ b/x11-libs/gl2ps/gl2ps-1.3.9.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit cmake-utils multilib
+
+DESCRIPTION="OpenGL to PostScript printing library"
+HOMEPAGE="http://www.geuz.org/gl2ps/"
+SRC_URI="http://geuz.org/${PN}/src/${P}.tgz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="doc png zlib"
+
+RDEPEND="
+	media-libs/freeglut
+	x11-libs/libXmu
+	png? ( media-libs/libpng:0= )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+	doc? (
+		dev-tex/tth
+		dev-texlive/texlive-latex
+		dev-texlive/texlive-latexrecommended )"
+
+S=${WORKDIR}/${P}-source
+
+PATCHES=( "${FILESDIR}"/${PN}-1.3.8-cmake.patch )
+
+src_prepare() {
+	cmake-utils_src_prepare
+	sed '/^install.*TODO\.txt/d' -i "${S}"/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_DOCDIR="share/doc/${PF}"
+		-DUSE_ENABLE_DOC="$(usex doc)"
+		-DUSE_ENABLE_PNG="$(usex png)"
+		-DUSE_ENABLE_ZLIB="$(usex zlib)"
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	if [[ ${CHOST} == *-darwin* ]] ; then
+		install_name_tool \
+			-id "${EPREFIX}"/usr/$(get_libdir)/libgl2ps.dylib \
+			"${D%/}${EPREFIX}"/usr/$(get_libdir)/libgl2ps.dylib || die
+	fi
+}