x11-libs/libva: bump to v2.11.0

The shell grouping patch is not needed any more as it has been
integrated upstream.

Signed-off-by: Karlson2k (Evgeny Grin) <k2k@narod.ru>
Closes: https://github.com/gentoo/gentoo/pull/20227
Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 101 insertions, 9 deletions

diff --git a/x11-libs/libva/Manifest b/x11-libs/libva/Manifest
index 1fd0cc02324e..5a80f469f0ef 100644
--- a/x11-libs/libva/Manifest
+++ b/x11-libs/libva/Manifest
@@ -5,3 +5,4 @@ DIST libva-2.7.1.tar.bz2 477933 BLAKE2B 261e608af3f1427bed0244d4ebbc0d3ffe568166
 DIST libva-2.8.0.tar.bz2 478734 BLAKE2B b11393a9b9ec7ef4cf91d20d4005d42ad3d0e6a4a8e4d8cda67816bc5b9d3b23900754b5e8af92386dcf99a11e53af70fc4723ffecc715328c8fbf3d40486098 SHA512 329c5fc2262a6f4fddfcb13bd9644589248be6ae18fa1481cccc6b33874b91b60ad3f16a1777712f7a4817ba576db984834aa8735e6ad13d99b2f5aa13e9ddfa
 DIST libva-2.9.0.tar.bz2 481556 BLAKE2B 5509f3d7df11a11602331a3b6bb78d3a5d3dfbeff024eaa77594918c49cd48ec9e8ee017d8ac7b4aa1dbd3252a23caecce9a10a8a9e12ef4c483a8a34e028b20 SHA512 496358b73cd525d8c9dc1fcf3dbf992ec997ecc8f7be31f0e226ded173aecf29d8d4b60cc7cc5ee7beac538061659841145f67f449a03a04236a6ee7ae6f8323
 DIST libva-2.9.1.tar.gz 240934 BLAKE2B 76333a9ce78783c3d94798a19ea6a52d95768ca7e5a547094290313d4f5c610841787d4420d19e0553174933beaf5fbf68e7e849ad38682173f670de0d9a76e5 SHA512 79fd0b41795ac5de68bdd6470389fad6caf016fa4a44f2cd775c0a65d6d8f270a7e237d3b2e42a90376c103d2d2e2c010fe47835c7a15d79b94beaced02a2884
+DIST libva-2.11.0.tar.gz 252204 BLAKE2B b56c47296493a9ecce7758661386d98d9a47082d8f16ab3b352f84591291e85aefc336a209433a901f7c4be1f54570221e9955666b22125740cc060542099394 SHA512 592df16bca06c93d252d27b2105032f020b0ca30f7937533918a497f385ec59b8a1e19c5d89047c197ddc1aab056128ab114b9ec29de3e968cb96bfa8d85f02a
diff --git a/x11-libs/libva/libva-2.11.0.ebuild b/x11-libs/libva/libva-2.11.0.ebuild
new file mode 100644
index 000000000000..953e353bda47
--- /dev/null
+++ b/x11-libs/libva/libva-2.11.0.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools multilib-minimal
+
+DESCRIPTION="Video Acceleration (VA) API for Linux"
+HOMEPAGE="https://01.org/linuxmedia/vaapi"
+
+if [[ ${PV} = *9999 ]] ; then
+	inherit git-r3
+	EGIT_BRANCH=master
+	EGIT_REPO_URI="https://github.com/intel/libva"
+else
+	# SRC_URI="https://github.com/intel/libva/releases/download/${PV}/${P}.tar.bz2"
+	# The upstream provides periodically tarball with pre-built 'configure'.
+	# To simplify updates, portage use tarballs without pre-build 'configure'
+	# which are always available.
+	SRC_URI="https://github.com/intel/libva/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="MIT"
+SLOT="0/$(ver_cut 1)"
+IUSE="+drm opengl utils vdpau wayland X"
+
+VIDEO_CARDS="nvidia intel i965 nouveau"
+for x in ${VIDEO_CARDS}; do
+	IUSE+=" video_cards_${x}"
+done
+
+RDEPEND="
+	>=x11-libs/libdrm-2.4.60[${MULTILIB_USEDEP}]
+	opengl? ( >=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}] )
+	wayland? (
+		>=dev-libs/wayland-1.11[${MULTILIB_USEDEP}]
+		dev-util/wayland-scanner[${MULTILIB_USEDEP}]
+	)
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXfixes-5.0.1[${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+"
+PDEPEND="video_cards_nvidia? ( >=x11-libs/libva-vdpau-driver-0.7.4-r1[${MULTILIB_USEDEP}] )
+	video_cards_nouveau? ( >=x11-libs/libva-vdpau-driver-0.7.4-r3[${MULTILIB_USEDEP}] )
+	vdpau? ( >=x11-libs/libva-vdpau-driver-0.7.4-r1[${MULTILIB_USEDEP}] )
+	video_cards_intel? ( >=x11-libs/libva-intel-driver-2.0.0[${MULTILIB_USEDEP}] )
+	video_cards_i965? ( >=x11-libs/libva-intel-driver-2.0.0[${MULTILIB_USEDEP}] )
+	utils? ( media-video/libva-utils )
+"
+
+REQUIRED_USE="|| ( drm wayland X )
+	opengl? ( X )"
+
+DOCS=( NEWS )
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/va/va_backend_glx.h
+	/usr/include/va/va_x11.h
+	/usr/include/va/va_dri2.h
+	/usr/include/va/va_dricommon.h
+	/usr/include/va/va_glx.h
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--with-drivers-path="${EPREFIX}/usr/$(get_libdir)/va/drivers"
+		$(use_enable opengl glx)
+		$(use_enable X x11)
+		$(use_enable wayland)
+		$(use_enable drm)
+		--enable-va-messaging
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	default
+	find "${ED}" -type f -name "*.la" -delete || die
+}
diff --git a/x11-libs/libva/libva-9999.ebuild b/x11-libs/libva/libva-9999.ebuild
index 812111b4ebad..045f07425bd6 100644
--- a/x11-libs/libva/libva-9999.ebuild
+++ b/x11-libs/libva/libva-9999.ebuild
@@ -3,23 +3,21 @@
 
 EAPI=7
 
-inherit multilib-minimal
+inherit autotools multilib-minimal
 
 DESCRIPTION="Video Acceleration (VA) API for Linux"
 HOMEPAGE="https://01.org/linuxmedia/vaapi"
 
-inherit autotools
-
 if [[ ${PV} = *9999 ]] ; then
 	inherit git-r3
 	EGIT_BRANCH=master
 	EGIT_REPO_URI="https://github.com/intel/libva"
 else
-	# SRC_URI="https://github.com/intel/libva/releases/download/${PV}/${P}.tar.bz2"
+	SRC_URI="https://github.com/intel/libva/releases/download/${PV}/${P}.tar.bz2"
 	# The upstream provides periodically tarball with pre-built 'configure'.
 	# To simplify updates, portage use tarballs without pre-build 'configure'
 	# which are always available.
-	SRC_URI="https://github.com/intel/libva/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	# SRC_URI="https://github.com/intel/libva/archive/${PV}.tar.gz -> ${P}.tar.gz"
 	KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
 fi
 
@@ -33,9 +31,12 @@ for x in ${VIDEO_CARDS}; do
 done
 
 RDEPEND="
-	>=x11-libs/libdrm-2.4.46[${MULTILIB_USEDEP}]
+	>=x11-libs/libdrm-2.4.60[${MULTILIB_USEDEP}]
 	opengl? ( >=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}] )
-	wayland? ( >=dev-libs/wayland-1.11[${MULTILIB_USEDEP}] )
+	wayland? (
+		>=dev-libs/wayland-1.11[${MULTILIB_USEDEP}]
+		dev-util/wayland-scanner[${MULTILIB_USEDEP}]
+	)
 	X? (
 		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
 		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
@@ -57,8 +58,7 @@ PDEPEND="video_cards_nvidia? ( >=x11-libs/libva-vdpau-driver-0.7.4-r1[${MULTILIB
 REQUIRED_USE="|| ( drm wayland X )
 	opengl? ( X )"
 
-# CONTRIBUTING.md and README.md are avaialbe only in .tar.gz tarballs and in git
-DOCS=( NEWS CONTRIBUTING.md README.md )
+DOCS=( NEWS )
 
 MULTILIB_WRAPPED_HEADERS=(
 	/usr/include/va/va_backend_glx.h