proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 54 insertions, 0 deletions

diff --git a/x11-misc/wmakerconf/wmakerconf-2.12-r1.ebuild b/x11-misc/wmakerconf/wmakerconf-2.12-r1.ebuild
new file mode 100644
index 000000000000..13808a5c7f18
--- /dev/null
+++ b/x11-misc/wmakerconf/wmakerconf-2.12-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+inherit eutils
+
+DESCRIPTION="X based config tool for the windowmaker X windowmanager"
+HOMEPAGE="http://wmakerconf.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P/-/_}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="imlib nls perl"
+
+RDEPEND="x11-libs/gtk+:2
+	>=x11-wm/windowmaker-0.95.2
+	imlib? ( media-libs/imlib )
+	perl? ( dev-lang/perl
+		dev-perl/HTML-Parser
+		|| ( dev-perl/libwww-perl
+		www-client/lynx
+		net-misc/wget ) )"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )
+	virtual/pkgconfig"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-wmaker-0.95_support.patch
+}
+
+src_configure() {
+	local myconf
+	use imlib || myconf="--disable-imlibtest"
+
+	econf \
+		$(use_enable perl upgrade) \
+		$(use_enable nls) \
+		${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" gnulocaledir="${ED}/usr/share/locale" install
+	dodoc AUTHORS ChangeLog MANUAL NEWS README TODO
+	doman man/*.1
+
+	rm -f "${ED}"/usr/share/${PN}/{AUTHORS,README,COPYING,NEWS,MANUAL,ABOUT-NLS,NLS-TEAM1,ChangeLog}
+}
+
+pkg_postinst() {
+	elog "New features added with WindowMaker >= 0.95 will not be available in wmakerconf"
+	elog "WPrefs is the recommended configuration tool"
+}