x11-misc/xaos: Port to EAPI 7

Bug: https://bugs.gentoo.org/776418
Closes: https://bugs.gentoo.org/726212
Closes: https://bugs.gentoo.org/732414
Closes: https://bugs.gentoo.org/742824
Package-Manager: Portage-3.0.17, Repoman-3.0.2
Signed-off-by: David Seifert <soap@gentoo.org>

1 files changed, 46 insertions, 50 deletions

diff --git a/x11-misc/xaos/xaos-3.6.ebuild b/x11-misc/xaos/xaos-3.6.ebuild
index 8f8963c98d1b..b882b13e3fe1 100644
--- a/x11-misc/xaos/xaos-3.6.ebuild
+++ b/x11-misc/xaos/xaos-3.6.ebuild
@@ -1,51 +1,52 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
+EAPI=7
 
-AUTOTOOLS_AUTORECONF=1
-AUTOTOOLS_IN_SOURCE_BUILD=1
-
-inherit autotools-utils eutils
+inherit autotools desktop
 
 DESCRIPTION="Very fast real-time fractal zoomer"
 HOMEPAGE="http://matek.hu/xaos/doku.php"
-SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
+SRC_URI="
+	mirror://sourceforge/${PN}/${P}.tar.gz
 	https://dev.gentoo.org/~jlec/distfiles/${PN}.png.tar"
 
-SLOT="0"
 LICENSE="GPL-2"
+SLOT="0"
 KEYWORDS="amd64 ppc sparc x86 ~amd64-linux ~x86-linux"
 IUSE="aalib doc -gtk nls png svga threads X"
 
 RDEPEND="
-	sci-libs/gsl:0=
-	sys-libs/zlib:0=
-	aalib? ( media-libs/aalib:0= )
-	gtk? ( x11-libs/gtk+:2= )
-	nls? ( sys-devel/gettext )
+	sci-libs/gsl:=
+	sys-libs/zlib
+	aalib? ( media-libs/aalib )
+	gtk? ( x11-libs/gtk+:2 )
 	png? ( media-libs/libpng:0= )
-	X? ( x11-libs/libX11:0=
-		 x11-libs/libXext:0=
-		 x11-libs/libXxf86vm:0= )"
-
+	X? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXxf86vm
+	)"
 DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )"
+BDEPEND="
 	virtual/pkgconfig
 	doc? ( virtual/texi2dvi )
-	X? ( x11-base/xorg-proto )"
+	nls? ( sys-devel/gettext )"
 
 PATCHES=(
-	"${FILESDIR}"/${PN}-3.4-png.patch
+	"${FILESDIR}"/${PN}-3.6-buildsystem.patch
 	"${FILESDIR}"/${PN}-3.4-include.patch
 	"${FILESDIR}"/${PN}-3.5-build-fix-i686.patch
-	"${FILESDIR}"/${PN}-3.6-locale-dir.patch
-	"${FILESDIR}"/${PN}-3.6-no-auto-strip.patch
 )
 
 src_prepare() {
-	autotools-utils_src_prepare
+	default
+	mv configure.{in,ac} || die
+	eautoreconf
+
 	if use nls; then
-		if [[ "${LINGUAS+set}" == "set" ]]; then
+		if [[ ${LINGUAS+set} == set ]]; then
 			strip-linguas -i src/i18n
 			sed -i -e '/^ALL_LINGUAS=/d' configure || die
 			export ALL_LINGUAS="${LINGUAS}"
@@ -56,41 +57,36 @@ src_prepare() {
 }
 
 src_configure() {
-	local myeconfargs=(
-		--with-sffe=yes
-		--with-gsl=yes
-		$(use_enable nls)
-		$(use_with png)
-		$(use_with aalib aa-driver)
-		$(use_with gtk gtk-driver)
-		$(use_with threads pthread)
-		$(use_with X x11-driver)
+	econf \
+		--with-sffe=yes \
+		--with-gsl=yes \
+		$(use_enable nls) \
+		$(use_with png) \
+		$(use_with aalib aa-driver) \
+		$(use_with gtk gtk-driver) \
+		$(use_with threads pthread) \
+		$(use_with X x11-driver) \
 		$(use_with X x)
-	)
-	autotools-utils_src_configure
 }
 
 src_compile() {
-	autotools-utils_src_compile
+	default
+
 	if use doc; then
-		cd "${BUILD_DIR}"/doc
-		emake xaos.dvi
-		dvipdf xaos.dvi || die
-		cd "${BUILD_DIR}"/help
-		emake html
+		emake -C doc xaos.dvi
+		dvipdf doc/xaos.dvi || die
+
+		emake -C help html
+		rm -r help/rest || die
+		HTML_DOCS=( help/. )
 	fi
 }
 
 src_install() {
-	autotools-utils_src_install
-	if use doc; then
-		insinto /usr/share/doc/${PF}
-		doins doc/xaos.pdf
-		dohtml -r help/*
-	fi
-	local driver="x11"
-	use gtk && driver="\"GTK+ Driver\""
-	make_desktop_entry "xaos -driver ${driver}" "XaoS Fractal Zoomer" \
-		xaos "Application;Education;Math;Graphics;"
+	default
+	use doc && dodoc xaos.pdf
+
+	make_desktop_entry "xaos -driver $(usex gtk '"GTK+ Driver"' x11)" "XaoS Fractal Zoomer" \
+		xaos "Education;Math;Graphics;"
 	doicon "${WORKDIR}"/${PN}.png
 }