x11-terms/st: add 0.8.5

This reverts commit 2a6d918cc0b6dfcc5d3e2e3af2d510ddd978f7ee.

PR: https://github.com/gentoo/gentoo/pull/18326
Bug: https://bugs.gentoo.org/592332
Co-authored-by: Ferenc Erki <erkiferenc@gmail.com>
Signed-off-by: Ferenc Erki <erkiferenc@gmail.com>
Signed-off-by: Georgy Yakovlev <gyakovlev@gentoo.org>

1 files changed, 75 insertions, 0 deletions

diff --git a/x11-terms/st/st-0.8.5.ebuild b/x11-terms/st/st-0.8.5.ebuild
new file mode 100644
index 000000000000..defaa3e758e2
--- /dev/null
+++ b/x11-terms/st/st-0.8.5.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop savedconfig toolchain-funcs
+
+DESCRIPTION="Simple terminal implementation for X"
+HOMEPAGE="https://st.suckless.org/"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.suckless.org/${PN}"
+else
+	SRC_URI="https://dl.suckless.org/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="MIT-with-advertising"
+SLOT="0"
+
+RDEPEND="
+	>=sys-libs/ncurses-6.0:0=
+	media-libs/fontconfig
+	x11-libs/libX11
+	x11-libs/libXft
+	~x11-terms/st-terminfo-${PV}
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "/^X11LIB/{s:/usr/X11R6/lib:/usr/$(get_libdir)/X11:}" \
+		-e '/^STLDFLAGS/s|= .*|= $(LDFLAGS) $(LIBS)|g' \
+		-e '/^X11INC/{s:/usr/X11R6/include:/usr/include/X11:}' \
+		config.mk || die
+	sed -i \
+		-e '/tic/d' \
+		Makefile || die
+
+	restore_config config.h
+}
+
+src_configure() {
+	sed -i \
+		-e "s|pkg-config|$(tc-getPKG_CONFIG)|g" \
+		config.mk || die
+
+	tc-export CC
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}"/usr install
+
+	dodoc TODO
+
+	make_desktop_entry ${PN} simpleterm utilities-terminal 'System;TerminalEmulator;' ''
+
+	save_config config.h
+}
+
+pkg_postinst() {
+	if ! [[ "${REPLACING_VERSIONS}" ]]; then
+		elog "Please ensure a usable font is installed, like"
+		elog "    media-fonts/corefonts"
+		elog "    media-fonts/dejavu"
+		elog "    media-fonts/urw-fonts"
+	fi
+}