x11-themes/adwaita-qt: Support qt6

Signed-off-by: Pacho Ramos <pacho@gentoo.org>

1 files changed, 55 insertions, 0 deletions

diff --git a/x11-themes/adwaita-qt/adwaita-qt-1.4.2-r1.ebuild b/x11-themes/adwaita-qt/adwaita-qt-1.4.2-r1.ebuild
new file mode 100644
index 000000000000..87e4cf45f272
--- /dev/null
+++ b/x11-themes/adwaita-qt/adwaita-qt-1.4.2-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit cmake
+
+DESCRIPTION="A style to bend Qt applications to look like they belong into GNOME Shell"
+HOMEPAGE="https://github.com/FedoraQt/adwaita-qt"
+SRC_URI="https://github.com/FedoraQt/${PN}/archive/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="gnome +qt5 qt6"
+REQUIRED_USE="|| ( qt5 qt6 )"
+
+DEPEND="
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtdbus:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtx11extras:5
+	)
+	qt6? ( dev-qt/qtbase:6[dbus,gui,widgets] )
+"
+RDEPEND="${DEPEND}"
+PDEPEND="gnome? ( x11-themes/QGnomePlatform )"
+
+src_configure() {
+	if use qt5; then
+		BUILD_DIR="${WORKDIR}/${PN}_qt5"
+		local mycmakeargs=(-DUSE_QT6=OFF)
+		cmake_src_configure
+	fi
+	if use qt6; then
+		BUILD_DIR="${WORKDIR}/${PN}_qt6"
+		local mycmakeargs=(-DUSE_QT6=ON)
+		cmake_src_configure
+	fi
+}
+
+src_compile() {
+	local _d
+	for _d in "${WORKDIR}"/${PN}_qt*; do
+		cmake_src_compile -C "${_d}"
+	done
+}
+
+src_install() {
+	local _d
+	for _d in "${WORKDIR}"/${PN}_qt*; do
+		cmake_src_install -C "${_d}"
+	done
+}