x11-themes/gentoo-artwork: EAPI-7 bump, missing || die, sort IUSE

drop superfluous dodir

Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 36 insertions, 40 deletions

diff --git a/x11-themes/gentoo-artwork/gentoo-artwork-0.4.2-r1.ebuild b/x11-themes/gentoo-artwork/gentoo-artwork-0.4.2-r1.ebuild
index dc4b33a158cc..274e05b862ba 100644
--- a/x11-themes/gentoo-artwork/gentoo-artwork-0.4.2-r1.ebuild
+++ b/x11-themes/gentoo-artwork/gentoo-artwork-0.4.2-r1.ebuild
@@ -1,17 +1,19 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI="5"
+EAPI=7
 
 BI_VER="20060811"
 
-DESCRIPTION="A collection of miscellaneous Gentoo Linux logos and artwork"
-SRC_URI="pixmaps? (
+DESCRIPTION="Collection of miscellaneous Gentoo Linux logos and artwork"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Artwork"
+SRC_URI="
+	pixmaps? (
 		mirror://gentoo/gentoo-artwork-0.2.tar.bz2
 		mirror://gentoo/gentoo-artwork-0.3.tar.bz2
 		mirror://gentoo/gentoo-artwork-0.4.tar.bz2
 		mirror://gentoo/gentoo-artwork-0.4.1.tar.bz2
-		mirror://gentoo/gentoo-artwork-0.4.2.tar.bz2
+		mirror://gentoo/gentoo-artwork-${PV}.tar.bz2
 		icons? ( mirror://gentoo/gentoo-bubble-icons-${BI_VER}.tar.gz )
 	)
 	!pixmaps? (
@@ -19,7 +21,7 @@ SRC_URI="pixmaps? (
 			mirror://gentoo/gentoo-artwork-0.2.tar.bz2
 			mirror://gentoo/gentoo-artwork-0.3.tar.bz2
 			mirror://gentoo/gentoo-artwork-0.4.tar.bz2
-			mirror://gentoo/gentoo-artwork-0.4.2.tar.bz2
+			mirror://gentoo/gentoo-artwork-${PV}.tar.bz2
 			mirror://gentoo/gentoo-bubble-icons-${BI_VER}.tar.gz
 		)
 		!icons? (
@@ -28,36 +30,32 @@ SRC_URI="pixmaps? (
 			lilo? ( mirror://gentoo/gentoo-artwork-0.4.tar.bz2 )
 		)
 	)"
-HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Artwork"
 
-KEYWORDS="~alpha amd64 ~mips ppc ppc64 sparc x86"
 LICENSE="GPL-2"
 SLOT="0"
-IUSE="kde offensive +icons +pixmaps +grub lilo"
+KEYWORDS="~alpha amd64 ~mips ppc ppc64 sparc x86"
+IUSE="+grub +icons kde lilo offensive +pixmaps"
 RESTRICT="binchecks strip"
 
-DEPEND=""
-RDEPEND="${DEPEND}"
-
 src_unpack() {
-	mkdir -p "${WORKDIR}"/${PN}-0.2
+	mkdir -p "${WORKDIR}"/${PN}-0.2 || die
 	if use pixmaps || use icons || use kde || use grub; then
 		unpack ${PN}-0.2.tar.bz2
 	fi
 	# rename unpacked dir so that updated files get overwritten
-	mv "${WORKDIR}"/${PN}-0.2 "${WORKDIR}"/${PN}-0.3
+	mv "${WORKDIR}"/${PN}-0.2 "${WORKDIR}"/${PN}-0.3 || die
 	if use pixmaps || use icons; then
 		unpack gentoo-artwork-0.3.tar.bz2
 	fi
-	mv "${WORKDIR}"/${PN}-0.3 "${WORKDIR}"/${PN}-0.4
+	mv "${WORKDIR}"/${PN}-0.3 "${WORKDIR}"/${PN}-0.4 || die
 	if use pixmaps || use icons || use lilo; then
 		unpack ${PN}-0.4.tar.bz2
 	fi
-	mv "${WORKDIR}"/${PN}-0.4 "${WORKDIR}"/${PN}-0.4.1
+	mv "${WORKDIR}"/${PN}-0.4 "${WORKDIR}"/${PN}-0.4.1 || die
 	if use pixmaps; then
 		unpack ${PN}-0.4.1.tar.bz2
 	fi
-	mv "${WORKDIR}"/${PN}-0.4.1 "${WORKDIR}"/${PN}-0.4.2
+	mv "${WORKDIR}"/${PN}-0.4.1 "${WORKDIR}"/${PN}-0.4.2 || die
 	if use pixmaps || use icons; then
 		unpack ${PN}-0.4.2.tar.bz2
 	fi
@@ -65,47 +63,47 @@ src_unpack() {
 	if use icons ; then
 		# Gentoo Bubble Icons
 		unpack gentoo-bubble-icons-${BI_VER}.tar.gz
-		cd "${WORKDIR}"/${PN}-0.4.2/icons/gentoo
+		cd "${WORKDIR}"/${PN}-0.4.2/icons/gentoo || die
 
-		cp "${FILESDIR}"/index.theme .
+		cp "${FILESDIR}"/index.theme . || die
 
-		mv l33t/l33t_BRO_lynx.png l33t/l33t_BRO_lynx2.png
-		mv "${WORKDIR}"/gentoo-bubble-icons/README bubble-icons-README
+		mv l33t/l33t_BRO_lynx.png l33t/l33t_BRO_lynx2.png || die
+		mv "${WORKDIR}"/gentoo-bubble-icons/README bubble-icons-README || die
 		find "${WORKDIR}"/gentoo-bubble-icons -name '*.png' \
-			-exec mv "{}" l33t/ \;
+			-exec mv "{}" l33t/ \; || die
 
 		# fix errors in filenames
-		mv l33t/l33t_nero.png l33t/l33t_UTI_nero.png
+		mv l33t/l33t_nero.png l33t/l33t_UTI_nero.png || die
 		# fix permissions (bug #213385)
 		fperms 644 l33t/l33t_MAI_mutt.png
 
 		# remove misspelled files
-		rm "${S}"/icons/gentoo/{32x32,48x48,64x64}/slypheed.png
+		rm "${S}"/icons/gentoo/{32x32,48x48,64x64}/slypheed.png || die
 	fi
 
 	if use pixmaps ; then
 		# bug #132271
-		rm "${S}"/pixmaps/1024x768/gentoo-blue-leaf-1024x768.jpg
-		rm "${S}"/pixmaps/1024x768/gentoo-blue-ute-1024x768.jpg
+		rm "${S}"/pixmaps/1024x768/gentoo-blue-leaf-1024x768.jpg || die
+		rm "${S}"/pixmaps/1024x768/gentoo-blue-ute-1024x768.jpg || die
 
 		# move images with wrong size to misc
 		mv "${S}"/pixmaps/800x600/OpenSource_in_the_sun-1280x960.png \
-			"${S}"/pixmaps/misc/OpenSource_in_the_sun-1280x960.png
+			"${S}"/pixmaps/misc/OpenSource_in_the_sun-1280x960.png || die
 		mv "${S}"/pixmaps/1024x768/Gentoo_2parts_1024x768.png \
-			"${S}"/pixmaps/misc/Gentoo_2parts_1024x786.png
+			"${S}"/pixmaps/misc/Gentoo_2parts_1024x786.png || die
 		mv "${S}"/pixmaps/1024x768/Gentoo_transparant_1024x768.png \
-			"${S}"/pixmaps/misc/Gentoo_transparant_960x768.png
+			"${S}"/pixmaps/misc/Gentoo_transparant_960x768.png || die
 		mv "${S}"/pixmaps/1280x1024/gentoo-freedom-1280x1024,jpg \
-			"${S}"/pixmaps/misc/gentoo-freedom-1280x1012.jpg
+			"${S}"/pixmaps/misc/gentoo-freedom-1280x1012.jpg || die
 		mv "${S}"/pixmaps/1280x1024/gentoowired.jpg \
-			"${S}"/pixmaps/misc/gentoowired-1280x960.jpg
+			"${S}"/pixmaps/misc/gentoowired-1280x960.jpg || die
 		mv "${S}"/pixmaps/1600x1200/gentoo-slip-1600x1200.jpg \
-			"${S}"/pixmaps/misc/gentoo-slip-1200x1024.jpg
+			"${S}"/pixmaps/misc/gentoo-slip-1200x1024.jpg || die
 	fi
 
 	if ! use offensive ; then
 		for i in $(<"${FILESDIR}"/offensive_list) ; do
-			rm -f "${S}/${i}"
+			rm "${S}/${i}" || die
 		done
 	fi
 }
@@ -114,9 +112,9 @@ src_install() {
 	if use pixmaps ; then
 		# pixmaps
 		dodir /usr/share/pixmaps/gentoo/
-		cd "${S}"/pixmaps
-		cp -pPR . "${D}"/usr/share/pixmaps/gentoo/
-		rm "${D}"/usr/share/pixmaps/gentoo/CREDITS
+		cd "${S}"/pixmaps || die
+		cp -pPR . "${D}"/usr/share/pixmaps/gentoo/ || die
+		rm "${D}"/usr/share/pixmaps/gentoo/CREDITS || die
 		dodoc "${S}"/pixmaps/CREDITS
 	fi
 
@@ -129,22 +127,20 @@ src_install() {
 	if use icons ; then
 		# Gentoo icons
 		dodir /usr/share/icons/gentoo
-		cp -pR "${S}"/icons/gentoo/* "${D}"/usr/share/icons/gentoo/
+		cp -pR "${S}"/icons/gentoo/* "${D}"/usr/share/icons/gentoo/ || die
 	fi
 
 	if use grub ; then
 		# grub splash images
-		dodir /usr/share/grub/splashimages
 		insinto /usr/share/grub/splashimages
 		doins "${S}"/grub/*.xpm.gz
 	fi
 
 	if use lilo ; then
 		# lilo splash images
-		dodir /usr/share/lilo/splashimages
 		insinto /usr/share/lilo/splashimages
 		doins "${S}"/lilo/*
-		rm "${D}"/usr/share/lilo/splashimages/lilo.txt
+		rm "${D}"/usr/share/lilo/splashimages/lilo.txt || die
 		dodoc "${S}"/lilo/lilo.txt
 	fi
 }