summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndrey Grozin <grozin@gentoo.org>2018-05-27 17:15:37 +0700
committerAndrey Grozin <grozin@gentoo.org>2018-05-27 17:15:37 +0700
commitf6a8222042139764516f9e70bbcda27e3a32cb10 (patch)
treea14d85a021716f3b26df2e8a076aabd366583eb9 /x11-wm/lumina
parentdev-libs/judy: Drop old (diff)
downloadgentoo-f6a8222042139764516f9e70bbcda27e3a32cb10.tar.gz
gentoo-f6a8222042139764516f9e70bbcda27e3a32cb10.tar.bz2
gentoo-f6a8222042139764516f9e70bbcda27e3a32cb10.zip
x11-wm/lumina: ebuild cleanup; depend on dev-qt/qtprintsupport
Suggested-by: PhobosK <phobosk@fastmail.fm> Closes: https://bugs.gentoo.org/640242 Closes: https://bugs.gentoo.org/652860 Package-Manager: Portage-2.3.19, Repoman-2.3.6
Diffstat (limited to 'x11-wm/lumina')
-rw-r--r--x11-wm/lumina/lumina-1.4.0_p1-r1.ebuild92
1 files changed, 92 insertions, 0 deletions
diff --git a/x11-wm/lumina/lumina-1.4.0_p1-r1.ebuild b/x11-wm/lumina/lumina-1.4.0_p1-r1.ebuild
new file mode 100644
index 00000000000..27374bbd02d
--- /dev/null
+++ b/x11-wm/lumina/lumina-1.4.0_p1-r1.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PLOCALES="af ar az bg bn bs ca cs cy da de el en_AU en_GB en_ZA es et eu fa fi fr fr_CA fur gl he hi hr hu id is it ja ka ko lt lv mk mn ms mt nb ne nl pa pl pt pt_BR ro ru sa sk sl sr sv sw ta tg th tr uk ur uz vi zh_CN zh_HK zh_TW zu"
+
+inherit qmake-utils l10n xdg-utils gnome2-utils
+DESCRIPTION="Lumina desktop environment"
+HOMEPAGE="https://lumina-desktop.org/"
+SRC_URI="https://github.com/trueos/${PN}/archive/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="desktop-utils"
+
+COMMON_DEPEND="dev-qt/qtcore:5
+ dev-qt/qtconcurrent:5
+ dev-qt/qtmultimedia:5[widgets]
+ dev-qt/qtsvg:5
+ dev-qt/qtnetwork:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtx11extras:5
+ dev-qt/qtgui:5
+ dev-qt/qtdeclarative:5
+ dev-qt/qtprintsupport:5
+ x11-libs/libxcb:0
+ x11-libs/xcb-util
+ x11-libs/xcb-util-image
+ x11-libs/xcb-util-wm
+ desktop-utils? ( app-text/poppler[qt5] )"
+
+DEPEND="$COMMON_DEPEND
+ dev-qt/linguist-tools:5"
+
+RDEPEND="$COMMON_DEPEND
+ sys-fs/inotify-tools
+ x11-misc/numlockx
+ x11-wm/fluxbox
+ || ( x11-apps/xbacklight
+ sys-power/acpilight )
+ media-sound/alsa-utils
+ sys-power/acpi
+ app-admin/sysstat"
+
+S="${WORKDIR}/${P/_/-}"
+
+PATCHES=(
+ "${FILESDIR}/1.2.0-desktop-files.patch"
+ "${FILESDIR}/1.4.0-poppler.patch"
+)
+
+DOCS=( README.md )
+
+src_prepare(){
+ default
+
+ if use !desktop-utils ; then
+ rm -rf src-qt5/desktop-utils || die
+ sed -e "/desktop-utils/d" -i src-qt5/src-qt5.pro || die
+ fi
+
+ l10n_find_plocales_changes "${S}/src-qt5/core/${PN}-desktop/i18n" "${PN}-desktop_" '.ts'
+}
+
+src_configure(){
+ eqmake5 PREFIX="${EPREFIX}/usr" LIBPREFIX="${EPREFIX}/usr/$(get_libdir)" \
+ CONFIG+=WITH_I18N QMAKE_CFLAGS_ISYSTEM=
+}
+
+src_install(){
+ emake install INSTALL_ROOT="${D}"
+ einstalldocs
+
+ remove_locale() {
+ rm -f "${ED%/}"/usr/share/${PN}-desktop/i18n/l*_${1}.qm
+
+ }
+ l10n_for_each_disabled_locale_do remove_locale
+}
+
+pkg_postinst() {
+ xdg_desktop_database_update
+ xdg_mimeinfo_database_update
+ gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+ xdg_desktop_database_update
+ xdg_mimeinfo_database_update
+ gnome2_icon_cache_update
+}