proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 71 insertions, 0 deletions

diff --git a/xfce-base/xfce4-session/xfce4-session-4.12.1.ebuild b/xfce-base/xfce4-session/xfce4-session-4.12.1.ebuild
new file mode 100644
index 000000000000..eba4548fef0e
--- /dev/null
+++ b/xfce-base/xfce4-session/xfce4-session-4.12.1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+EAUTORECONF=1
+inherit xfconf
+
+DESCRIPTION="A session manager for the Xfce desktop environment"
+HOMEPAGE="http://docs.xfce.org/xfce/xfce4-session/start"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 ~sparc x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="debug nls policykit systemd upower +xscreensaver"
+
+COMMON_DEPEND=">=dev-libs/dbus-glib-0.100:=
+	x11-apps/iceauth
+	x11-libs/libSM:=
+	>=x11-libs/libwnck-2.30:1=
+	x11-libs/libX11:=
+	>=xfce-base/libxfce4util-4.11:=
+	>=xfce-base/libxfce4ui-4.12.1:=
+	>=xfce-base/xfconf-4.10:=
+	!xfce-base/xfce-utils
+	!=xfce-base/libxfce4ui-4.12.0
+	policykit? ( >=sys-auth/polkit-0.102:= )
+	upower? ( || ( >=sys-power/upower-0.9.23 sys-power/upower-pm-utils ) )"
+RDEPEND="${COMMON_DEPEND}
+	x11-apps/xrdb
+	nls? ( x11-misc/xdg-user-dirs )
+	!systemd? ( upower? ( sys-power/pm-utils ) )
+	xscreensaver? ( || (
+		>=x11-misc/xscreensaver-5.26
+		gnome-extra/gnome-screensaver
+		>=x11-misc/xlockmore-5.43
+		x11-misc/slock
+		x11-misc/alock[pam]
+		) )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+REQUIRED_USE="systemd? ( policykit )"
+
+pkg_setup() {
+	PATCHES=( "${FILESDIR}"/${PN}-4.10.1-alock_support_to_xflock4.patch )
+
+	XFCONF=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		$(use_enable policykit polkit)
+		--with-xsession-prefix="${EPREFIX}"/usr
+		$(xfconf_use_debug)
+		)
+
+	use upower && XFCONF+=( --enable-upower )
+
+	DOCS=( AUTHORS BUGS ChangeLog NEWS README TODO )
+}
+
+src_install() {
+	xfconf_src_install
+
+	local sessiondir=/etc/X11/Sessions
+	echo startxfce4 > "${T}"/Xfce4
+	exeinto ${sessiondir}
+	doexe "${T}"/Xfce4
+	dosym Xfce4 ${sessiondir}/Xfce
+}