1 files changed, 55 insertions, 0 deletions
diff --git a/app-admin/lnav/lnav-0.11.1-r2.ebuild b/app-admin/lnav/lnav-0.11.1-r2.ebuild
new file mode 100644
index 000000000000..18fee38a20e9
--- /dev/null
+++ b/app-admin/lnav/lnav-0.11.1-r2.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools flag-o-matic
+
+DESCRIPTION="A curses-based tool for viewing and analyzing log files"
+HOMEPAGE="https://lnav.org"
+SRC_URI="https://github.com/tstack/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="pcap test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-arch/bzip2:0=
+	app-arch/libarchive:=
+	>=dev-db/sqlite-3.9.0
+	dev-libs/libpcre2
+	>=net-misc/curl-7.23.0
+	sys-libs/ncurses:=
+	sys-libs/readline:=
+	sys-libs/zlib:=
+	pcap? ( net-analyzer/wireshark[tshark] )"
+# The tests use ssh-keygen and use dsa and rsa keys (which is why ssl is required)
+DEPEND="${RDEPEND}
+	test? (
+		virtual/openssh[ssl]
+		dev-cpp/doctest
+	)"
+
+DOCS=( AUTHORS NEWS.md README )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.11.0-disable-tests.patch
+	"${FILESDIR}"/${PN}-0.11.1-0001-Fix-build-with-GCC-13-add-missing-cstdint-include.patch
+)
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	filter-lto
+
+	econf \
+		--disable-static \
+		--with-ncurses \
+		$(use_with test system-doctest)
+}