2 files changed, 56 insertions, 0 deletions
diff --git a/app-cdr/cdemu/Manifest b/app-cdr/cdemu/Manifest
index c8600db1ee7b..963a73ef0906 100644
--- a/app-cdr/cdemu/Manifest
+++ b/app-cdr/cdemu/Manifest
@@ -1 +1,2 @@
 DIST cdemu-client-3.2.3.tar.bz2 44311 BLAKE2B 23451618897a5281478c9d70ded357089a4baaf47b22f36b4add9c5d2c899478629ce034cce0e593b501a127cdc1f5527f0aaf1951f709bf4c2d131e898045a2 SHA512 5d98870fa42bb639009dc6971747f252f3403eda882bffacf55f647193a1a9fb7a75ad69a7512da3abdcdeb64510b0f163ea997c4d75a804fa93880b62b03dd6
+DIST cdemu-client-3.2.4.tar.bz2 44284 BLAKE2B c57fe09bef7112933a93fac9944eaff957e01692ec1ddec7fd443aa780f8b3d85d0bd640611337d896843de3ab00d09e093c293776a52afa85f781bdde7f4250 SHA512 2e10cb345e261ddaa6da68ee626770ed65749b1ea64c2bbbf0f3a2e96184c2906834886754e87e3161c3056473e5ee0dc20672ce7cb48232e6bef1c93cb80550
diff --git a/app-cdr/cdemu/cdemu-3.2.4.ebuild b/app-cdr/cdemu/cdemu-3.2.4.ebuild
new file mode 100644
index 000000000000..03c5e30d84a7
--- /dev/null
+++ b/app-cdr/cdemu/cdemu-3.2.4.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit bash-completion-r1 cmake-utils python-single-r1 xdg-utils
+
+MY_P=cdemu-client-${PV}
+DESCRIPTION="Command-line tool for controlling cdemu-daemon"
+HOMEPAGE="https://cdemu.sourceforge.io"
+SRC_URI="https://download.sourceforge.net/cdemu/cdemu-client/${MY_P}.tar.bz2"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+cdemu-daemon"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_MULTI_USEDEP}]
+	')
+	cdemu-daemon? ( app-cdr/cdemu-daemon:0/7 )"
+BDEPEND="${PYTHON_DEPS}
+	dev-util/desktop-file-utils
+	>=dev-util/intltool-0.21
+	>=sys-devel/gettext-0.18
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS README )
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	python_fix_shebang src/cdemu
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPOST_INSTALL_HOOKS=OFF
+		-DCMAKE_INSTALL_COMPLETIONSDIR="$(get_bashcompdir)"
+	)
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}