1 files changed, 32 insertions, 0 deletions
diff --git a/app-misc/terminal-colors/terminal-colors-3.0.2.ebuild b/app-misc/terminal-colors/terminal-colors-3.0.2.ebuild
new file mode 100644
index 000000000000..f127d91a60d5
--- /dev/null
+++ b/app-misc/terminal-colors/terminal-colors-3.0.2.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE="ncurses"
+
+inherit python-r1
+
+DESCRIPTION="A tool to display color charts for 8, 16, 88, and 256 color terminals"
+HOMEPAGE="http://zhar.net/projects/shell/terminal-colors"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/eikenb/terminal-colors.git"
+else
+	SRC_URI="https://github.com/eikenb/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="amd64 x86 ~x64-macos"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}"
+BDEPEND="${PYTHON_DEPS}"
+
+src_compile() { :; }
+
+src_install() {
+	python_foreach_impl python_newscript ${PN} ${PN}
+	einstalldocs
+}