1 files changed, 41 insertions, 0 deletions
diff --git a/app-shells/thefuck/thefuck-3.27.ebuild b/app-shells/thefuck/thefuck-3.27.ebuild
new file mode 100644
index 000000000000..9216446f6ddc
--- /dev/null
+++ b/app-shells/thefuck/thefuck-3.27.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+inherit distutils-r1
+
+DESCRIPTION="Magnificent app which corrects your previous console command"
+HOMEPAGE="https://github.com/nvbn/thefuck"
+SRC_URI="https://github.com/nvbn/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	dev-python/psutil[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/decorator[${PYTHON_USEDEP}]
+	dev-python/colorama[${PYTHON_USEDEP}]
+	dev-python/pyte[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)"
+
+python_prepare_all() {
+	sed -i -e "/import pip/s/^/#/" -e "/pip.__version__/,+3 s/^/#/" setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	py.test || die
+}