1 files changed, 65 insertions, 0 deletions
diff --git a/app-text/libetonyek/libetonyek-0.1.10-r2.ebuild b/app-text/libetonyek/libetonyek-0.1.10-r2.ebuild
new file mode 100644
index 000000000000..4cad77ca17f5
--- /dev/null
+++ b/app-text/libetonyek/libetonyek-0.1.10-r2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/libreoffice/libetonyek.git"
+	inherit autotools git-r3
+else
+	SRC_URI="https://dev-www.libreoffice.org/src/libetonyek/${P}.tar.xz"
+	KEYWORDS="amd64 ~arm arm64 ~loong ppc64 ~riscv x86"
+fi
+
+DESCRIPTION="Library parsing Apple Keynote presentations"
+HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libetonyek"
+
+LICENSE="|| ( GPL-2+ LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+IUSE="doc static-libs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-text/liblangtag
+	dev-libs/librevenge
+	dev-libs/libxml2
+	>=dev-util/mdds-2.0:1=
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+	media-libs/glm
+	dev-build/libtool
+	test? ( dev-util/cppunit )
+"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-text/doxygen )
+"
+
+src_prepare() {
+	default
+	[[ -d m4 ]] || mkdir "m4"
+	[[ ${PV} == *9999* ]] && eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-werror
+		$(use_with doc docs)
+		$(use_enable static-libs static)
+		$(use_enable test tests)
+	)
+	if has_version ">=dev-util/mdds-2.1"; then
+		myeconfargs+=( --with-mdds=2.1 )
+	else
+		myeconfargs+=( --with-mdds=2.0 )
+	fi
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -type f -delete || die
+}