1 files changed, 48 insertions, 0 deletions
diff --git a/app-text/lv/lv-4.51-r5.ebuild b/app-text/lv/lv-4.51-r5.ebuild
new file mode 100644
index 000000000000..58fee6c0a2bb
--- /dev/null
+++ b/app-text/lv/lv-4.51-r5.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools toolchain-funcs
+
+MY_P="${PN}${PV//./}"
+
+DESCRIPTION="Powerful Multilingual File Viewer"
+HOMEPAGE="https://github.com/ttdoda/lv"
+SRC_URI="mirror://gentoo/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~arm ~ia64 ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE=""
+
+RDEPEND="!app-editors/levee
+	sys-libs/ncurses:0="
+DEPEND="${RDEPEND}"
+BDEPEND="dev-lang/perl"
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-gentoo.patch
+	"${FILESDIR}"/${PN}-headers.patch
+	"${FILESDIR}"/${PN}-tinfo.patch
+	"${FILESDIR}"/${PN}-xz.patch
+)
+DOCS=( README hello.sample )
+HTML_DOCS=( index.html relnote.html hello.sample.gif )
+
+src_prepare() {
+	default
+
+	cd src
+	mv configure.{in,ac}
+	eautoreconf
+}
+
+src_configure() {
+	ECONF_SOURCE=src econf
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)"
+}