1 files changed, 51 insertions, 0 deletions
diff --git a/app-text/pdfarranger/pdfarranger-1.8.1.ebuild b/app-text/pdfarranger/pdfarranger-1.8.1.ebuild
new file mode 100644
index 000000000000..cb9c3aeef2e5
--- /dev/null
+++ b/app-text/pdfarranger/pdfarranger-1.8.1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..10} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1 optfeature xdg-utils desktop
+
+DESCRIPTION="Merge or split pdfs; rearrange, rotate, crop pages."
+HOMEPAGE="https://github.com/jeromerobert/pdfarranger"
+SRC_URI="https://github.com/jeromerobert/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+RDEPEND="
+	app-text/poppler[introspection,cairo]
+	dev-python/pikepdf[${PYTHON_USEDEP}]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP},cairo]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	x11-libs/gtk+:3[introspection]
+	x11-libs/pango[introspection]
+"
+DEPEND="${RDEPEND}
+	dev-python/python-distutils-extra[${PYTHON_USEDEP}]
+"
+
+src_install() {
+	distutils-r1_src_install
+	for x in 16 32 48 256 scalable
+	do doicon -s ${x} data/icons/hicolor/${x}*/*
+	done
+}
+
+pkg_postinst() {
+	optfeature "image file import" media-gfx/img2pdf
+
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}