1 files changed, 31 insertions, 0 deletions
diff --git a/app-text/tree/tree-2.1.1.ebuild b/app-text/tree/tree-2.1.1.ebuild
new file mode 100644
index 000000000000..dd393b5c6efc
--- /dev/null
+++ b/app-text/tree/tree-2.1.1.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs flag-o-matic bash-completion-r1
+
+DESCRIPTION="Lists directories recursively, and produces an indented listing of files"
+HOMEPAGE="https://mama.indstate.edu/users/ice/tree/ https://gitlab.com/OldManProgrammer/unix-tree"
+SRC_URI="https://gitlab.com/OldManProgrammer/unix-${PN}/-/archive/${PV}/unix-${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~x64-macos"
+
+S=${WORKDIR}/unix-${P}
+
+src_compile() {
+	append-lfs-flags
+	emake \
+		CC="$(tc-getCC)" \
+		CFLAGS="${CFLAGS} ${CPPFLAGS}" \
+		LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	dobin tree
+	doman doc/tree*.1
+	einstalldocs
+	newbashcomp "${FILESDIR}"/${PN}.bashcomp ${PN}
+}