1 files changed, 55 insertions, 0 deletions
diff --git a/dev-ada/gnat_util/gnat_util-2016.ebuild b/dev-ada/gnat_util/gnat_util-2016.ebuild
new file mode 100644
index 000000000000..0fab74a0ea24
--- /dev/null
+++ b/dev-ada/gnat_util/gnat_util-2016.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit toolchain-funcs multiprocessing
+
+MYP=${PN}-gpl-${PV}
+
+DESCRIPTION="Provides access to GNAT compiler internals for AdaCore utilities"
+HOMEPAGE="http://libre.adacore.com"
+SRC_URI="http://mirrors.cdn.adacore.com/art/57399637c7a447658e0affa6 -> ${MYP}-src.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+shared static static-pic"
+
+RDEPEND="dev-lang/gnat-gpl"
+DEPEND="${RDEPEND}
+	dev-ada/gprbuild"
+
+S="${WORKDIR}"/${MYP}-src
+
+PATCHES=( "${FILESDIR}"/${P}-gentoo.patch )
+
+pkg_setup() {
+	GCC=${ADA:-$(tc-getCC)}
+	GNATMAKE="${GCC/gcc/gnatmake}"
+	if [[ -z "$(type ${GNATMAKE} 2>/dev/null)" ]] ; then
+		eerror "You need a gcc compiler that provides the Ada Compiler:"
+		eerror "1) use gcc-config to select the right compiler or"
+		eerror "2) set ADA=gcc-4.9.4 in make.conf"
+		die "ada compiler not available"
+	fi
+}
+
+src_compile() {
+	emake GNATMAKE=${GNATMAKE} BUILDER="gprbuild -j$(makeopts_jobs)" generate_sources
+	for kind in shared static static-pic; do
+		if use ${kind}; then
+			emake BUILDER="gprbuild -j$(makeopts_jobs)" build-${kind}
+		fi
+	done
+}
+
+src_install() {
+	for kind in shared static static-pic; do
+		if use ${kind}; then
+			emake prefix="${D}"/usr install-${kind}
+		fi
+	done
+	einstalldocs
+}