1 files changed, 40 insertions, 0 deletions
diff --git a/dev-cpp/gulrak-filesystem/gulrak-filesystem-1.5.12.ebuild b/dev-cpp/gulrak-filesystem/gulrak-filesystem-1.5.12.ebuild
new file mode 100644
index 000000000000..e35c0185bc92
--- /dev/null
+++ b/dev-cpp/gulrak-filesystem/gulrak-filesystem-1.5.12.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Header-only single-file std::filesystem compatible helper library"
+HOMEPAGE="https://github.com/gulrak/filesystem"
+SRC_URI="https://github.com/gulrak/filesystem/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 ~arm64 x86"
+IUSE="examples test"
+RESTRICT="!test? ( test )"
+
+S="${WORKDIR}/${P#*-}"
+
+src_prepare() {
+	cmake_src_prepare
+	sed -i "s:-Werror::g" cmake/GhcHelper.cmake test/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DGHC_FILESYSTEM_BUILD_EXAMPLES=OFF
+		-DGHC_FILESYSTEM_BUILD_TESTING=$(usex test)
+		-DGHC_FILESYSTEM_WITH_INSTALL=ON
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	docinto examples
+	use examples && dodoc examples/*.cpp
+}