1 files changed, 50 insertions, 0 deletions
diff --git a/dev-cpp/libjson-rpc-cpp/libjson-rpc-cpp-0.5.0.ebuild b/dev-cpp/libjson-rpc-cpp/libjson-rpc-cpp-0.5.0.ebuild
new file mode 100644
index 000000000000..62e02bd19abf
--- /dev/null
+++ b/dev-cpp/libjson-rpc-cpp/libjson-rpc-cpp-0.5.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit cmake-utils
+
+DESCRIPTION="JSON-RPC (1.0 & 2.0) framework for C++"
+HOMEPAGE="https://github.com/cinemast/libjson-rpc-cpp"
+SRC_URI="https://github.com/cinemast/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc +http-client +http-server +stubgen test"
+
+RDEPEND="
+	dev-libs/jsoncpp:=
+	http-client? ( net-misc/curl:= )
+	http-server? ( net-libs/libmicrohttpd:= )
+	stubgen? ( dev-libs/argtable:= )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	test? ( dev-libs/boost )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DHTTP_CLIENT=$(usex http-client)
+		-DHTTP_SERVER=$(usex http-server)
+		# they are not installed
+		-DCOMPILE_EXAMPLES=NO
+		-DCOMPILE_STUBGEN=$(usex stubgen)
+		-DCOMPILE_TESTS=$(usex test)
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	use doc && emake -C "${BUILD_DIR}" doc
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	use doc && dodoc -r "${BUILD_DIR}"/doc/html
+}