1 files changed, 55 insertions, 0 deletions
diff --git a/dev-cpp/tbb/tbb-2021.5.0-r1.ebuild b/dev-cpp/tbb/tbb-2021.5.0-r1.ebuild
new file mode 100644
index 000000000000..adb066b4c2d9
--- /dev/null
+++ b/dev-cpp/tbb/tbb-2021.5.0-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake-multilib flag-o-matic
+
+DESCRIPTION="High level abstract threading library"
+HOMEPAGE="https://github.com/oneapi-src/oneTBB"
+SRC_URI="https://github.com/oneapi-src/oneTBB/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/oneTBB-${PV}"
+
+LICENSE="Apache-2.0"
+# https://github.com/oneapi-src/oneTBB/blob/master/CMakeLists.txt#L53
+# libtbb<SONAME>-libtbbmalloc<SONAME>-libtbbbind<SONAME>
+SLOT="0/12.5-2.5-3.5"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ppc64 ~riscv ~sparc x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="!kernel_Darwin? ( sys-apps/hwloc:= )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	# should be in.. 2022?
+	"${FILESDIR}"/${PN}-2021.4.0-lto.patch
+	"${FILESDIR}"/${PN}-2021.5.0-musl-deepbind.patch
+	# bug 827883
+	"${FILESDIR}"/${PN}-2021.4.0-missing-TBB_machine_fetchadd4.patch
+	# need to verify this is in master
+	"${FILESDIR}"/${PN}-2021.5.0-musl-mallinfo.patch
+	# musl again, should be in.. 2022?
+	"${FILESDIR}"/${PN}-2021.5.0-musl-setcontext.patch
+	# should be in.. 2022?
+	"${FILESDIR}"/${PN}-2021.5.0-x86-mwaitpkg.patch
+
+	"${FILESDIR}"/${PN}-2021.5.0-flags-stripping.patch
+)
+
+src_configure() {
+	# Workaround for bug #912210
+	append-ldflags $(test-flags-CCLD -Wl,--undefined-version)
+
+	# Workaround for bug #912210
+	append-ldflags $(test-flags-CCLD -Wl,--undefined-version)
+
+	local mycmakeargs=(
+		-DTBB_TEST=$(usex test)
+		-DTBB_ENABLE_IPO=OFF
+		-DTBB_STRICT=OFF
+	)
+
+	cmake-multilib_src_configure
+}