1 files changed, 38 insertions, 0 deletions
diff --git a/dev-libs/hyphen/hyphen-2.8.8-r2.ebuild b/dev-libs/hyphen/hyphen-2.8.8-r2.ebuild
new file mode 100644
index 000000000000..cdc8be439f21
--- /dev/null
+++ b/dev-libs/hyphen/hyphen-2.8.8-r2.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="ALTLinux hyphenation library"
+HOMEPAGE="https://hunspell.github.io/"
+SRC_URI="https://downloads.sourceforge.net/hunspell/${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1 MPL-1.1"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ppc ppc64 ~riscv ~sparc x86 ~amd64-linux ~x86-linux"
+IUSE="static-libs"
+
+DEPEND="app-text/hunspell"
+RDEPEND="${DEPEND}"
+BDEPEND="dev-lang/perl"
+
+DOCS=( AUTHORS ChangeLog NEWS README{,.nonstandard,.hyphen,.compound} THANKS TODO )
+
+PATCHES=(
+	"${FILESDIR}"/${P}-mawk.patch
+)
+
+src_configure() {
+	econf $(use_enable static-libs static)
+}
+
+src_install() {
+	default
+
+	docinto pdf
+	dodoc doc/*.pdf
+
+	rm -r "${ED}"/usr/share/hyphen || die
+	# bug #775587
+	rm -f "${ED}/usr/$(get_libdir)/libhyphen.la" || die
+}