1 files changed, 43 insertions, 0 deletions
diff --git a/dev-libs/libcss/libcss-0.9.2.ebuild b/dev-libs/libcss/libcss-0.9.2.ebuild
new file mode 100644
index 000000000000..36b6fd1f2d52
--- /dev/null
+++ b/dev-libs/libcss/libcss-0.9.2.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit netsurf
+
+DESCRIPTION="CSS parser and selection engine, written in C"
+HOMEPAGE="https://www.netsurf-browser.org/projects/libcss/"
+SRC_URI="https://download.netsurf-browser.org/libs/releases/${P}-src.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/libparserutils
+	dev-libs/libwapcaplet"
+DEPEND="${RDEPEND}
+	test? ( dev-lang/perl )"
+BDEPEND="
+	dev-build/netsurf-buildsystem
+	virtual/pkgconfig"
+
+_emake() {
+	netsurf_define_makeconf
+	emake "${NETSURF_MAKECONF[@]}" COMPONENT_TYPE=lib-shared $@
+}
+
+src_compile() {
+	_emake
+}
+
+src_test() {
+	_emake test
+}
+
+src_install() {
+	_emake DESTDIR="${D}" install
+}