1 files changed, 82 insertions, 0 deletions
diff --git a/dev-libs/libnl/libnl-3.2.23.ebuild b/dev-libs/libnl/libnl-3.2.23.ebuild
new file mode 100644
index 000000000000..25cfb13442d0
--- /dev/null
+++ b/dev-libs/libnl/libnl-3.2.23.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 python3_3 )
+DISTUTILS_OPTIONAL=1
+inherit distutils-r1 eutils libtool multilib
+
+NL_P=${P/_/-}
+
+DESCRIPTION="A collection of libraries providing APIs to netlink protocol based Linux kernel interfaces"
+HOMEPAGE="http://www.infradead.org/~tgr/libnl/"
+SRC_URI="
+	http://www.infradead.org/~tgr/${PN}/files/${NL_P}.tar.gz
+"
+LICENSE="LGPL-2.1 utils? ( GPL-2 )"
+SLOT="3"
+KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 s390 sh sparc x86 ~amd64-linux ~ia64-linux ~x86-linux"
+IUSE="static-libs python utils"
+
+RDEPEND="python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}
+	python? ( dev-lang/swig )
+	sys-devel/flex
+	sys-devel/bison
+"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+DOCS=( ChangeLog )
+
+S=${WORKDIR}/${NL_P}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-1.1-vlan-header.patch
+	epatch "${FILESDIR}"/${PN}-3.2.20-rtnl_tc_get_ops.patch
+	epatch "${FILESDIR}"/${PN}-3.2.20-cache-api.patch
+	epatch "${FILESDIR}"/${PN}-3.2.23-python.patch
+
+	elibtoolize
+
+	if use python; then
+		cp "${FILESDIR}"/${P}-utils.h python/netlink/utils.h || die
+		cd "${S}"/python || die
+		distutils-r1_src_prepare
+	fi
+}
+
+src_configure() {
+	econf \
+		--disable-silent-rules \
+		$(use_enable static-libs static) \
+		$(use_enable utils cli)
+
+	if use python; then
+		cd "${S}"/python || die
+		distutils-r1_src_configure
+	fi
+}
+
+src_compile() {
+	default
+
+	if use python; then
+		cd "${S}"/python || die
+		distutils-r1_src_compile
+	fi
+}
+
+src_install() {
+	default
+
+	if use python; then
+		# Unset DOCS= since distutils-r1.eclass interferes
+		DOCS=''
+		cd "${S}"/python || die
+		distutils-r1_src_install
+	fi
+
+	prune_libtool_files $(usex static-libs --modules --all)
+}