5 files changed, 100 insertions, 4 deletions
diff --git a/dev-lua/lanes/Manifest b/dev-lua/lanes/Manifest
index a8b4f9f6ddd3..f6c85e118470 100644
--- a/dev-lua/lanes/Manifest
+++ b/dev-lua/lanes/Manifest
@@ -1 +1,2 @@
 DIST lanes-3.16.3.tar.gz 446289 BLAKE2B 018f470209b534bb84f69f8a38c7decd8011a13926bf7c82a4fc4b0d3f2892562a69c3116dd6fce5d37d9d2b5057ed661cc22bdbfcfac4e267a32dd5f64a47dc SHA512 a3037c0df27e8172ce9ff896079eb4a5ee3a35dc507a8b809c151de21e7600ffd0fccc12113fb64dc3c709e1eff99da350576aef41ac20493ea933fb7dc4c381
+DIST lanes-3.17.0.tar.gz 449193 BLAKE2B 110c05bdf46b9e5faf7e4ebf52992799fc2d1a993411a9488c75fc8134a267650348152299e91f94d1af8378a0e8a06c5485a364aad3cf246d7339006c89a924 SHA512 b9866cf1af54c758c840d2f6df3e14e6231f952b651d1196262a4b14d1361dd55697cba467998e90a69d876bcde5beffd25f3f8b53c387534b292650c25c357d
diff --git a/dev-lua/lanes/lanes-3.17.0.ebuild b/dev-lua/lanes/lanes-3.17.0.ebuild
new file mode 100644
index 000000000000..8baab79dd024
--- /dev/null
+++ b/dev-lua/lanes/lanes-3.17.0.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-{1..4} luajit )
+
+inherit lua toolchain-funcs
+
+DESCRIPTION="Lightweight, native, lazy evaluating multithreading library"
+HOMEPAGE="https://github.com/LuaLanes/lanes"
+SRC_URI="https://github.com/LuaLanes/lanes/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="test"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+# Tests are currently somehow problematic.
+# https://github.com/LuaLanes/lanes/issues/197
+# https://github.com/LuaLanes/lanes/issues/198
+RESTRICT="test"
+
+RDEPEND="${LUA_DEPS}"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	test? ( ${RDEPEND} )
+"
+
+HTML_DOCS=( "docs/." )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.13.0-makefile.patch"
+)
+
+src_prepare() {
+	default
+
+	lua_copy_sources
+}
+
+lua_src_compile() {
+	pushd "${BUILD_DIR}" || die
+
+	local myemakeargs=(
+		"CC=$(tc-getCC)"
+		"LUA=${ELUA}"
+		"LUA_FLAGS=$(lua_get_CFLAGS)"
+		"LUA_LIBS="
+		"OPT_FLAGS=${CFLAGS}"
+	)
+
+	tc-export PKG_CONFIG
+
+	emake "${myemakeargs[@]}"
+
+	popd
+}
+
+src_compile() {
+	lua_foreach_impl lua_src_compile
+}
+
+lua_src_test() {
+	pushd "${BUILD_DIR}" || die
+
+	emake LUA="${ELUA}" test
+
+	popd
+}
+
+src_test() {
+	lua_foreach_impl lua_src_test
+}
+
+lua_src_install() {
+	pushd "${BUILD_DIR}" || die
+
+	local myemakeargs=(
+		"LUA_LIBDIR=${ED}/$(lua_get_cmod_dir)"
+		"LUA_SHAREDIR=${ED}/$(lua_get_lmod_dir)"
+	)
+
+	emake "${myemakeargs[@]}" install
+
+	popd
+}
+
+src_install() {
+	lua_foreach_impl lua_src_install
+
+	einstalldocs
+}
diff --git a/dev-lua/luadbi/luadbi-0.7.3.ebuild b/dev-lua/luadbi/luadbi-0.7.3.ebuild
index ceace5bd8ac6..a018a850e8e3 100644
--- a/dev-lua/luadbi/luadbi-0.7.3.ebuild
+++ b/dev-lua/luadbi/luadbi-0.7.3.ebuild
@@ -13,7 +13,7 @@ SRC_URI="https://github.com/mwild1/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+KEYWORDS="amd64 arm arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc x86"
 IUSE="mysql postgres +sqlite test"
 REQUIRED_USE="
 	${LUA_REQUIRED_USE}
diff --git a/dev-lua/luarocks/luarocks-3.11.0.ebuild b/dev-lua/luarocks/luarocks-3.11.0.ebuild
index 2319a20303e0..780e6d75e53f 100644
--- a/dev-lua/luarocks/luarocks-3.11.0.ebuild
+++ b/dev-lua/luarocks/luarocks-3.11.0.ebuild
@@ -13,7 +13,7 @@ SRC_URI="https://luarocks.org/releases/${P}.tar.gz"
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+KEYWORDS="amd64 arm arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc x86"
 IUSE="test"
 REQUIRED_USE="${LUA_REQUIRED_USE}"
 RESTRICT="test"
diff --git a/dev-lua/lutok/lutok-0.4-r11.ebuild b/dev-lua/lutok/lutok-0.4-r11.ebuild
index c3e30ece373f..d68865e5ab6d 100644
--- a/dev-lua/lutok/lutok-0.4-r11.ebuild
+++ b/dev-lua/lutok/lutok-0.4-r11.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2017-2023 Gentoo Authors
+# Copyright 2017-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -12,7 +12,7 @@ SRC_URI="https://github.com/jmmv/lutok/releases/download/${P}/${P}.tar.gz"
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~ppc-macos ~x64-macos ~x64-solaris"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~ppc-macos ~x64-macos ~x64-solaris"
 IUSE="test"
 REQUIRED_USE="${LUA_REQUIRED_USE}"
 RESTRICT="!test? ( test )"