1 files changed, 46 insertions, 0 deletions
diff --git a/dev-python/beaker/beaker-1.6.4-r1.ebuild b/dev-python/beaker/beaker-1.6.4-r1.ebuild
new file mode 100644
index 000000000000..ee3e4d258b54
--- /dev/null
+++ b/dev-python/beaker/beaker-1.6.4-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+# py3.3 unfit with some types
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1
+
+MY_PN="Beaker"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="A Session and Caching library with WSGI Middleware"
+HOMEPAGE="http://beaker.groovie.org/ http://pypi.python.org/pypi/Beaker"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="alpha amd64 arm ~hppa ia64 ppc ~ppc64 s390 sh sparc x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE="test"
+
+# webtest-based tests are skipped when webtest is not installed
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/webtest[${PYTHON_USEDEP}] )"
+RDEPEND=""
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	# Workaround for http://bugs.python.org/issue11276.
+	sed -e "s/import anydbm/& as anydbm/;/import anydbm/a dbm = anydbm" \
+		-i beaker/container.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	cp -r -l tests "${BUILD_DIR}"/ || die
+	pushd  "${BUILD_DIR}"/tests > /dev/null
+	nosetests || die "Tests fail with ${EPYTHON}"
+	popd > /dev/null
+}