1 files changed, 62 insertions, 0 deletions
diff --git a/dev-python/fabric/fabric-2.2.2.ebuild b/dev-python/fabric/fabric-2.2.2.ebuild
new file mode 100644
index 000000000000..2ee141e59f00
--- /dev/null
+++ b/dev-python/fabric/fabric-2.2.2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_6 )
+
+inherit distutils-r1
+
+DESCRIPTION="A simple pythonic tool for remote execution and deployment"
+HOMEPAGE="http://fabfile.org https://pypi.org/project/Fabric/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="2"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc fab2 test"
+
+RDEPEND="
+	!fab2? ( !dev-python/fabric:0 )
+	>=dev-python/cryptography-1.1[${PYTHON_USEDEP}]
+	>=dev-python/invoke-1.0[${PYTHON_USEDEP}]
+	<dev-python/invoke-2.0
+	>=dev-python/paramiko-2.4[${PYTHON_USEDEP}]"
+
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/alabaster-0.7[${PYTHON_USEDEP}]
+		<dev-python/alabaster-2.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.4[${PYTHON_USEDEP}]
+		<dev-python/sphinx-1.7[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		>=dev-python/pytest-relaxed-1.1.4[${PYTHON_USEDEP}]
+	)"
+
+python_compile() {
+	if use fab2; then
+		export PACKAGE_AS_FABRIC2=1
+		ln -s fabric fabric2 || die
+	fi
+	distutils-r1_python_compile
+}
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build -b html -c sites/docs/ sites/docs/ sites/docs/html || die
+	fi
+}
+
+python_test() {
+	# -p pytest_relaxed: this plugin has to be loaded explicitly
+	pytest -s -v -p pytest_relaxed.plugin || die "Tests failed"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( sites/docs/html/. )
+	distutils-r1_python_install_all
+}