1 files changed, 65 insertions, 0 deletions
diff --git a/dev-python/pylint/pylint-1.7.1.ebuild b/dev-python/pylint/pylint-1.7.1.ebuild
new file mode 100644
index 000000000000..1c5b2098c547
--- /dev/null
+++ b/dev-python/pylint/pylint-1.7.1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="Python code static checker"
+HOMEPAGE="
+	http://www.logilab.org/project/pylint
+	https://pypi.python.org/pypi/pylint
+	https://github.com/pycqa/pylint"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~x86"
+IUSE="doc examples test"
+
+RDEPEND="
+	>=dev-python/astroid-1.5.1[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	>=dev-python/isort-4.2.5[${PYTHON_USEDEP}]
+	dev-python/mccabe
+	$(python_gen_cond_dep '
+		dev-python/backports-functools-lru-cache[${PYTHON_USEDEP}]
+		dev-python/configparser[${PYTHON_USEDEP}]' python2_7)"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( ${RDEPEND} )"
+
+RESTRICT="test" # multiple failures
+
+# Usual. Requ'd for impl specific failures in test phase
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_compile_all() {
+	# selection of straight html triggers a trivial annoying bug, we skirt it
+	use doc && PYTHONPATH="${S}" emake -e -C doc singlehtml
+}
+
+python_test() {
+	${EPYTHON} \
+		-m unittest discover \
+		-s pylint/test/ -p "*test_*".py \
+		--verbose || die
+}
+
+python_install_all() {
+	doman man/{pylint,pyreverse}.1
+	if use examples ; then
+		docinto examples
+		dodoc -r examples/.
+	fi
+	use doc && local HTML_DOCS=( doc/_build/singlehtml/. )
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	# Optional dependency on "tk" USE flag would break support for Jython.
+	optfeature "pylint-gui script requires dev-lang/python with \"tk\" USE flag enabled." dev-lang/python[tk]
+}