1 files changed, 37 insertions, 0 deletions
diff --git a/dev-python/six/six-9999.ebuild b/dev-python/six/six-9999.ebuild
new file mode 100644
index 000000000000..f0d81184fb98
--- /dev/null
+++ b/dev-python/six/six-9999.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4} pypy pypy3 )
+
+inherit distutils-r1 mercurial
+
+DESCRIPTION="Python 2 and 3 compatibility library"
+HOMEPAGE="https://bitbucket.org/gutworth/six http://pypi.python.org/pypi/six"
+SRC_URI=""
+EHG_REPO_URI="https://bitbucket.org/gutworth/six"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS=""
+IUSE="doc test"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx )
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+python_compile_all() {
+	use doc && emake -C documentation html
+}
+
+python_test() {
+	py.test -v || die "Testing failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( documentation/_build/html/ )
+	distutils-r1_python_install_all
+}