1 files changed, 45 insertions, 0 deletions
diff --git a/dev-python/testtools/testtools-1.7.1.ebuild b/dev-python/testtools/testtools-1.7.1.ebuild
new file mode 100644
index 000000000000..44d5c42f1941
--- /dev/null
+++ b/dev-python/testtools/testtools-1.7.1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="Extensions to the Python standard library unit testing framework"
+HOMEPAGE="https://github.com/testing-cabal/testtools"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc64"
+IUSE="doc"
+
+CDEPEND="
+	dev-python/extras[${PYTHON_USEDEP}]
+	dev-python/mimeparse[${PYTHON_USEDEP}]
+	>=dev-python/unittest2-1.0.0[${PYTHON_USEDEP}]
+	dev-python/traceback2[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+"
+RDEPEND="${CDEPEND}"
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_test() {
+	"${PYTHON}" -m testtools.run testtools.tests.test_suite || die "tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( doc/_build/html/. )
+
+	distutils-r1_python_install_all
+}