1 files changed, 43 insertions, 0 deletions
diff --git a/dev-python/webob/webob-1.7.4.ebuild b/dev-python/webob/webob-1.7.4.ebuild
new file mode 100644
index 000000000000..41ff9c6ff0ea
--- /dev/null
+++ b/dev-python/webob/webob-1.7.4.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} pypy )
+
+inherit distutils-r1 versionator
+
+MY_PN=WebOb
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="WSGI request and response object"
+HOMEPAGE="http://webob.org/ https://pypi.python.org/pypi/WebOb"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="doc test"
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/coverage[${PYTHON_USEDEP}] )"
+RDEPEND=""
+
+S=${WORKDIR}/${MY_P}
+
+python_compile_all() {
+	if use doc; then
+		esetup.py build_sphinx
+	fi
+}
+
+python_test() {
+	nosetests --verbose -w tests || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
+	distutils-r1_python_install_all
+}