1 files changed, 56 insertions, 0 deletions
diff --git a/dev-ruby/rake/rake-12.3.0.ebuild b/dev-ruby/rake/rake-12.3.0.ebuild
new file mode 100644
index 000000000000..712e7522cf9e
--- /dev/null
+++ b/dev-ruby/rake/rake-12.3.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+USE_RUBY="ruby22 ruby23 ruby24"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_EXTRADOC="CHANGES README.rdoc TODO"
+
+RUBY_FAKEGEM_TASK_TEST=""
+
+RUBY_FAKEGEM_BINDIR="exe"
+
+inherit bash-completion-r1 ruby-fakegem
+
+DESCRIPTION="Make-like scripting in Ruby"
+HOMEPAGE="https://github.com/ruby/rake"
+SRC_URI="https://github.com/ruby/rake/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc"
+
+DEPEND+=" app-arch/gzip"
+
+ruby_add_bdepend "test? ( >=dev-ruby/minitest-5.8 )
+	doc? ( dev-ruby/rdoc )"
+
+all_ruby_prepare() {
+	sed -i -e '/coverall/I s:^:#:' test/helper.rb || die
+}
+
+all_ruby_compile() {
+	if use doc; then
+		rdoc --title "Rake - Ruby Make" --main README.rdoc --out html lib *.rdoc doc/*/*.rdoc || die
+	fi
+}
+
+each_ruby_test() {
+	${RUBY} -Ilib:test:. -e 'gem "minitest", "~>5.8"; require "minitest/autorun"; Dir["test/test_*.rb"].each{|f| require f}' || die
+}
+
+all_ruby_install() {
+	ruby_fakegem_binwrapper rake
+
+	if use doc; then
+		pushd html
+		dodoc -r *
+		popd
+	fi
+
+	doman doc/rake.1
+
+	newbashcomp "${FILESDIR}"/rake.bash-completion ${PN}
+}