summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'dev-ruby/rcairo/rcairo-1.15.3.ebuild')
-rw-r--r--dev-ruby/rcairo/rcairo-1.15.3.ebuild76
1 files changed, 76 insertions, 0 deletions
diff --git a/dev-ruby/rcairo/rcairo-1.15.3.ebuild b/dev-ruby/rcairo/rcairo-1.15.3.ebuild
new file mode 100644
index 00000000000..603c95644d8
--- /dev/null
+++ b/dev-ruby/rcairo/rcairo-1.15.3.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+USE_RUBY="ruby20 ruby21 ruby22 ruby23"
+
+RUBY_FAKEGEM_NAME="cairo"
+
+# Documentation depends on files that are not distributed.
+RUBY_FAKEGEM_TASK_DOC=""
+
+RUBY_FAKEGEM_TASK_TEST=""
+
+RUBY_FAKEGEM_DOCDIR="doc"
+
+RUBY_FAKEGEM_EXTRADOC="AUTHORS NEWS"
+
+inherit multilib ruby-fakegem
+
+DESCRIPTION="Ruby bindings for cairo"
+HOMEPAGE="https://cairographics.org/rcairo/"
+
+IUSE=""
+
+SLOT="0"
+LICENSE="|| ( Ruby GPL-2 )"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+RDEPEND="${RDEPEND}
+ >=x11-libs/cairo-1.2.0[svg]"
+DEPEND="${DEPEND}
+ >=x11-libs/cairo-1.2.0[svg]"
+
+ruby_add_bdepend "
+ dev-ruby/pkg-config
+ dev-ruby/ruby-glib2
+ test? ( >=dev-ruby/test-unit-2.1.0-r1:2 )"
+
+all_ruby_prepare() {
+ # Avoid development dependency.
+ sed -i -e '/notify/ s:^:#:' test/cairo-test-utils.rb || die
+}
+
+each_ruby_configure() {
+ ${RUBY} -Cext/cairo extconf.rb || die "extconf failed"
+}
+
+each_ruby_compile() {
+ emake V=1 -Cext/cairo
+
+ # again, try to make it more standard, to install it more easily.
+ cp ext/cairo/cairo$(get_modname) lib/ || die
+}
+
+each_ruby_test() {
+ # don't rely on the Rakefile because it's a mess to load with
+ # their hierarchy, do it manually.
+ ${RUBY} -Ilib -r ./test/cairo-test-utils.rb \
+ -e 'gem "test-unit"; require "test/unit"; Dir.glob("test/**/test_*.rb") {|f| load f}' || die "tests failed"
+}
+
+each_ruby_install() {
+ each_fakegem_install
+
+ insinto $(ruby_get_hdrdir)
+ doins ext/cairo/rb_cairo.h
+}
+
+all_ruby_install() {
+ all_fakegem_install
+
+ insinto /usr/share/doc/${PF}/samples
+ doins -r samples/*
+}