1 files changed, 82 insertions, 0 deletions
diff --git a/dev-util/global/global-6.3.1.ebuild b/dev-util/global/global-6.3.1.ebuild
new file mode 100644
index 000000000000..a7b694e9b2e3
--- /dev/null
+++ b/dev-util/global/global-6.3.1.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+inherit autotools elisp-common eutils
+
+DESCRIPTION="GNU Global is a tag system to find the locations of a specified object in various sources"
+HOMEPAGE="http://www.gnu.org/software/global/global.html"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="amd64 ppc x86 ~x86-fbsd"
+IUSE="doc emacs vim"
+
+RDEPEND="|| ( dev-libs/libltdl:0 sys-devel/libtool:2 )
+	sys-libs/ncurses
+	emacs? ( virtual/emacs )
+	vim? ( || ( app-editors/vim app-editors/gvim ) )"
+DEPEND="${DEPEND}
+	doc? ( app-text/texi2html sys-apps/texinfo )"
+
+SITEFILE="50gtags-gentoo.el"
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-6.2.9-tinfo.patch"
+	eautoreconf
+}
+
+src_configure() {
+	econf "$(use_with emacs lispdir "${SITELISP}/${PN}")"
+}
+
+src_compile() {
+	if use doc; then
+		texi2pdf -q -o doc/global.pdf doc/global.texi
+		texi2html -o doc/global.html doc/global.texi
+	fi
+
+	if use emacs; then
+		elisp-compile *.el
+	fi
+
+	emake
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	if use doc; then
+		dohtml doc/global.html
+		# doc/global.pdf is generated if tex executable (e.g. /usr/bin/tex) is available.
+		[[ -f doc/global.pdf ]] && dodoc doc/global.pdf
+	fi
+
+	dodoc AUTHORS FAQ NEWS README THANKS
+
+	insinto /etc
+	doins gtags.conf
+
+	if use vim; then
+		insinto /usr/share/vim/vimfiles/plugin
+		doins gtags.vim
+	fi
+
+	if use emacs; then
+		elisp-install ${PN} *.{el,elc}
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	fi
+
+	prune_libtool_files
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}